Science/circle_sample.tl

#   Copyright (c) 2024 MBARI
#   MBARI Proprietary Information. Confidential. All Rights Reserved
#   Unauthorized copying or distribution of this file via any medium is strictly
#   prohibited.
#
#   WARNING - This file contains information whose export is restricted by the
#   Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
#   amended. Violations of these export laws are subject to severe civil and/or
#   criminal penalties.

mission CircleSample {
  arguments {
    # Almost every mission should start with an overall timeout and a NeedCommsTime. Drift Missions will have an acoustic timeout instead of a NeedCommsTime.

    # You probably need to change these.

    NumSamplers = 1 count
      """
      Total number of ESP cartridges (Maximum 60).
      """

    # debug
    #    </Description><Units:count/><Value>2</Value></DefineArg>

    MissionTimeout = 24 hour
      """
      Maximum duration of mission
      """

    AcousticTrackingTimeout = 24 hour
      """
      If the vehicle does not receive an acoustic signal for more than this
      length of time, it will surface for communications. Set longer than
      MissionTimeout to effectively disable.
      """

    NeedCommsTimeVeryLong = 240 hour
      """
      How often to surface for commumications during sampling. Huge number to
      disable needcomms during sampling.
      """

    NeedCommsTimeYoYo = 1 hour
      """
      How often to surface for commumications during yoyo profiling
      """

    GPSTimeout = 10 minute
      """
      Maximum amount of time to spend trying to get each GPS fix.
      """

    NeedCommsMissionStart = true
      """
      Whether to run NeedComms at start of mission.
      """

    UseOtherLRAUVSignals = false
      """
      Whether to use the other LRAUV's sample start and completion signals to
      trigger sampling.
      """

    # debug
    #             </Description><True/></DefineArg>

    TrackAcousticTarget = true
      """
      Whether to track an acoustic target.
      """

    # debug
    #    </Description><False/></DefineArg>

    AcousticTargetContactLabel = 21 count
      """
      The acoustic address of the asset to be tracked
      """

    AcousticTargetDepth = NaN meter
      """
      Depth of acoustic target if known and fixed (or nearly fixed). For
      example, if the acoustic target is a Wave Glider, set it to zero. This
      will improve 2D projected position estimates in the Earth reference
      frame. Defaults to NaN.
      """

    AcousticTargetContactTimeout = 15 minute
      """
      Only use a sufficiently fresh handshake to update the tracking center.
      """

    YoYoWhenNotSampling = true
      """
      If true: Yoyo when not sampling. If false: maintaining one depth when not sampling.
      """

    YoYoWhenSampling = false
      """
      If true: Yoyo when sampling. If false: maintaining one depth when sampling.
      """

    SampleChl = false
      """
      Whether to sample at chl peak depth reported by another LRAUV.
      """

    ThreshChl = 0 microgram_per_liter
      """
      When OtherLRAUVReportedPeakChl exceeds this threshold, assign the sampling depth to OtherLRAUVReportedPeakDepth.
      """

    SamplePlanktivoreLM = false
      """
      Whether to sample at PlanktivoreLM peak depth reported by another LRAUV.
      """

    ThreshPlanktivoreLM = 0 count_per_second
      """
      When OtherLRAUVReportedPeakPlanktivoreLM exceeds this threshold, assign the sampling depth to OtherLRAUVReportedPeakDepth.
      """

    SendSampleResultToWG = true
      """
      Whether to send sample result to Wave Glider.
      """

    ModemIDofWG = 21 enum
      """
      Modem ID of Wave Glider. Initialized to 1.
      """

    SendMessageTerminateMission = false
      """
      Whether to send terminateMission message to the other LRAUV.
      """

    ModemIDofOtherLRAUV = 4 enum
      """
      Modem ID of the other LRAUV. Initialized to 4.
      """

    WaitBeforeFiring = 5 minute
      """
      Used only when UseOtherLRAUVSignals is True: wait time before firing the next sample to listen to the other LRAUV's
      sample start signal. No less than 5 minutes.
      """

    MaxWaitFirstSampleOtherLRAUVSampleStartNotReceived = 10 minute
      """
      For the 1st sample, if not receiving the other LRAUV's sample start
      signal after longer than MaxWaitFirstSample, fire.
      """

    MaxWaitFirstSampleOtherLRAUVSampleStartReceived = 2 hour
      """
      For the 1st sample, if having received the other LRAUV's sample start
      signal (but having not received the other LRAUV's sample completed
      signal) after longer than MaxWaitFirstSampleOtherLRAUVSampleStartReceived, fire.
      """

    MaxWaitNotAchievingDepth = 0.5 hour
      """
      Maximum wait time the vehicle cannot reach the targeted depth.
      """

    WaitSendMessage = 2 minute
      """
      Wait time for transmitting the terminateMission message to the other LRAUV.
      """

    SpeedSampling = 1.0 meter_per_second
      """
      Vehicle speed when sampling on circle.
      """

    SendMessageDepth = 10 meter
      """
      Depth for sending the terminateMission message.
      """

    MaxDepth = 50 meter
      """
      Maximum depth for the entire mission.
      """

    CircleRadius = 20 meter
      """
      Radius of circle centered at the Wave Glider latitude and longitude.
      """

    MaxNumCircles = 10000 count
      """
      Maximum number of circles.
      """

    CenterLatitude = NaN degree
      """
      The latitude of the center of the circle. Fill this in to specify a
      start position, it will be overwritten once the vehicle receives an
      acoustic signal from the contact.
      """

    # debug
    #    </Description><Units:degree/><Value>36.80</Value></DefineArg>

    CenterLongitude = NaN degree
      """
      The longitude of the center of the circle. Fill this in to specify a
      start position, it will be overwritten once the vehicle receives an
      acoustic signal from the contact.
      """

    # debug
    #    </Description><Units:degree/><Value>-121.82</Value></DefineArg>

    MaxWaitStopMissionCommon = 2 hour
      """
      Value common to all samples.
      """

    MaxWaitStopMission[1..60] = NaN hour
      """
      If no firing after more than MaxWaitStopMission, terminate mission.
      """

    MaxWaitFireEndToStartCommon = NaN minute
      """
      Value common to all samples unless set differently: if MaxWaitFireEndToStart has elapsed since the end of the last sampling, fire.
      """

    MaxWaitFireEndToStart[1..60] = NaN minute
      """
      If MaxWaitFireEndToStart has elapsed since the end of the last sampling, fire.
      """

    # debug
    #    </Description><Units:minute/><Value>120</Value></DefineArg>


    MaxWaitFireSinceFirstSampleStart[1..60] = NaN hour
      """
      For all samples, if MaxWaitFireSinceFirstSampleStart has elapsed since the start of the first sample, fire.
      """

    DepCircleCommon = NaN meter
      """
      Value common to all samples unless set differently: circle depth.
      """

    DepCircle[1..60] = NaN meter
      """
      Circle depth {$}.
      """

    CircleYoYoMinDepNotSamplingCommon = NaN meter
      """
      Value common to all samples unless set differently: minimum yoyo depth while circling when not sampling.
      """

    CircleYoYoMinDepNotSampling[1..60] = NaN meter
      """
      CircleYoYoMinDepNotSampling {$}.
      """

    CircleYoYoMaxDepNotSamplingCommon = NaN meter
      """
      Value common to all samples unless set differently: maximum yoyo depth while circling when not sampling.
      """

    CircleYoYoMaxDepNotSampling[1..60] = NaN meter
      """
      CircleYoYoMaxDepNotSampling {$}.
      """

    CircleYoYoMinDepSamplingCommon = NaN meter
      """
      Value common to all samples unless set differently: minimum yoyo depth while circling when sampling.
      """

    CircleYoYoMinDepSampling[1..60] = NaN meter
      """
      CircleYoYoMinDepSampling {$}.
      """

    CircleYoYoMaxDepSamplingCommon = NaN meter
      """
      Value common to all samples unless set differently: maximum yoyo depth while circling when sampling.
      """

    CircleYoYoMaxDepSampling[1..60] = NaN meter
      """
      CircleYoYoMaxDepSampling {$}.
      """

    SurfacingAfterSamplingCommon = false
      """
      Value common to all samples unless set differently: whether to surface after sampling.
      """

    SurfacingAfterSampling[1..60] = false
      """
      SurfacingAfterSampling {$}.
      """

    CartridgeTypeCommon = -1 count
      """
      Value common to all samples unless set diffently: cartridge type.
      """

    CartridgeType[1..60] = NaN count
      """
      Cartridge {$}.
      """

    SettleCommon = 1 minute
      """
      Settle time before firing. Value common to all samples except Sample 1.
      """

    Settle1 = 5 minute
      """
      Settle time before firing. Sample 1.
      """

    # Use caution when changing these.

    YoYoMinAltitude = 9 meter
      """
      Minimum altitude while performing the YoYo behavior (for
      bottom-terminated YoYos).
      """

    MinAltitude = 7 meter
      """
      Minimum altitude for the entire mission.
      """

    MinOffshore = 2 kilometer
      """
      Minimum offshore distance for the entire mission.
      """

    # You probably do not need to change these.

    IntervalRestartLogs = 24 hour

    TrackingUpdatePeriod = 60 second
      """
      How long to wait between acoustic queries
      """

    NumberOfPings = 1 count
      """
      Number of return pings to request with each acoustic query (more than 1
      will activate oneway mode)
      """

    NumberOfFixesLowPass = 4 count
      """
      Number of fixes to average to produce smoothed lat/lon/dep output
      (initialized to 4).
      """

    NumberOfStartingFixesToIgnore = 1 count
      """
      Number of fixes to ignore at the start of mission (as the vehicle just
      leaves surface, contact's location estimate especailly bearing can be
      erroneous. Initialized to 1, corresponding to 15 s if query
      interval TrackingUpdatePeriod = 15 s.
      """

    CircleMaxError = 100 meter
      """
      If this distance away from the circle, drive straight towards (or away
      from the center). Otherwise, try to reduce distance from the ideal
      circle.
      """

    CircleTurnToPort = false
      """
      If true, vehicle turns to the left around the center point. If false,
      vehicle turns to the right.
      """

    KwpHeading = 0.010 radian_per_meter
      """
      Used to relax waypoint cross-track error constant that is adjusted for
      docking. (You can override this setting by passing an argument.)
      """

    YoYoUpPitch = 20 degree
      """
      Vehicle up pitch while performing the YoYo behavior.
      """

    YoYoDownPitch = -20 degree
      """
      Vehicle down pitch while performing the YoYo behavior.
      """

    SurfacePitch = 20 degree
      """
      Pitch to maintain while ascending
      """

    BuoyancyNeutral = Control:VerticalControl.buoyancyNeutral
      """
      Buoyancy bladder position while performing the YoYo behavior. Defaults
      to buoyancyNeutral setting in the Config/Control.cfg file. Set to NaN cc
      for active buoyancy
      """

    MassDefault = Control:VerticalControl.massDefault
      """
      Static setting for mass during the mission. Set to NaN mm for active
      mass position
      """
  }

  output {
    # Internal variables that you should not change

    TerminateMissionMessageSent = false

    MaximumWaitStopMission = NaN hour

    MaxWaitStopMissionIndividual = NaN hour

    MaximumWaitFireEndToStart = NaN minute

    MaxWaitFireEndToStartIndividual = NaN minute

    MaximumWaitFireSinceFirstSampleStart = NaN minute

    MaxWaitFireSinceFirstSampleStartIndividual = NaN minute

    DepthCircle = NaN meter
      """
      Circle depth.
      """

    DepCircleIndividual = NaN meter
      """
      Circle depth for individual samples.
      """

    CircleYoYoMinDepthNotSampling = NaN meter
      """
      Minimum yoyo depth while circling when not sampling.
      """

    CircleYoYoMaxDepthNotSampling = NaN meter
      """
      Maximum yoyo depth while circling when not sampling.
      """

    CircleYoYoMinDepNotSamplingIndividual = NaN meter
      """
      Minimum yoyo depth when not sampling for individual samples.
      """

    CircleYoYoMaxDepNotSamplingIndividual = NaN meter
      """
      Maximum yoyo depth when not sampling for individual samples.
      """

    CircleYoYoMinDepthSampling = NaN meter
      """
      Minimum yoyo depth while circling when sampling.
      """

    CircleYoYoMaxDepthSampling = NaN meter
      """
      Maximum yoyo depth while circling when sampling.
      """

    CircleYoYoMinDepSamplingIndividual = NaN meter
      """
      Minimum yoyo depth when sampling for individual samples.
      """

    CircleYoYoMaxDepSamplingIndividual = NaN meter
      """
      Maximum yoyo depth when sampling for individual samples.
      """

    SurfaceAfterSampling = false
      """
      Whether to surface after sampling.
      """

    SurfacingAfterSamplingIndividual = false
      """
      Whether to surface after sampling.
      """

    CartridgeTypeIndividual = NaN count
      """
      Cartridge type individual.
      """

    CartType = -6 count
      """
      Cartridge type. Initialized to -6.
      """

    ElapsedSinceMissionStartOrLastSampleStart = 0 hour
      """
      The mission sets this variable at the completion of mission start or at the start of a sample (of this vehicle or the other vehicle).
      """

    ElapsedSinceFirstSampleStart = 0 hour
      """
      The mission sets this variable at the start of the first sample of this vehicle.
      """

    ElapsedSinceLastSampleEnd = 0 hour
      """
      The mission sets this variable at the completion of mission start or at the end of a sample (of this vehicle or the other vehicle).
      """

    ElapsedSinceLastCenterUpdate = 0 hour
      """
      The mission sets this variable to reset the center update timer.
      """

    ElapsedTime1 = 0 hour
      """
      Only for syslog.
      """

    ElapsedTime2 = 0 hour
      """
      Only for syslog.
      """

    SettleDuration = 5.0 minute
      """
      Settle time before firing a sample. Program will set for each sampler,
      e.g., Settle1 or SettleCommon.
      """

    StoppedForNoFiringForTooLong = false
      """
      Mission stopped because of no firing for too long. Initialized to false.
      """

    MissionStartCommsCompleted = false
      """
      MissionStartComms is completed (initialized to false).
      """

    FlagSamplingOngoing = false
      """
      Flag of water sampling in process (initialized to false).
      """

    SampleCompleted = false
      """
      Sampling completed. Initialized to false.
      """

    SampleOptionsSet = false
      """
      Sample options (DepDiffFromPeakChl, ReportAtSurface, ReacquirePeak)
      already set. Initialized to false.
      """

    OtherLRAUVSampleStartReceived = false
      """
      Whether the other LRAUV's sample start signal is received. Initialized
      to False.
      """

    OtherLRAUVSampleCompleteReceived = false
      """
      Whether the other LRAUV's sample completed signal is received.
      Initialized to False.
      """

    OtherLRAUVReportedPeakDepth = NaN meter
      """
      The peak-signal depth reported by the other LRAUV
      """

    OtherLRAUVReportedPeakDepthPreceding = NaN meter
      """
      The peak-signal depth on the preceding leg reported by the other LRAUV
      """

    CntSamples = 1 count
      """
      Count of water samples (initilized to 1).
      """

    TrueVar = true
      """
      A True boolean, defined as an arg because you can't directly place
      values in a call to SendData.
      """

    FiredOnMaxWait = false

    FiredOnReceivingOtherLRAUVSampleComplete = false

    OtherLRAUVReportedPeakChl = NaN microgram_per_liter

    OtherLRAUVReportedPeakPlanktivoreLM = NaN count_per_second
  }

  # Missions should almost always start with a timeout and a NeedComms aggregate. Drift missions will not use NeedComms.

  timeout duration=MissionTimeout

  insert id="NeedComms" Insert/NeedComms.tl

  assign in sequence NeedComms:DiveInterval = NeedCommsTimeVeryLong

  # Missions should almost always start with standard safety envelopes

  insert Insert/StandardEnvelopes.tl

  assign in sequence StandardEnvelopes:MinAltitude = MinAltitude

  assign in sequence StandardEnvelopes:MaxDepth = MaxDepth

  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore

  behavior Sample:AbortSample {
    run in parallel
  }

  insert Insert/AbortDrift.tl {
    redefineArg AcousticTimeout = AcousticTrackingTimeout
  }

  insert Insert/SampleAtDepth.tl {
    redefineArg MaxWaitNotReachingDepth = MaxWaitNotAchievingDepth
  }

  insert Insert/Sample.tl

  # Many missions will keep mass position fixed at the default.

  behavior Guidance:Pitch {
    run in parallel

    set massPosition = MassDefault
  }

  insert Insert/Science.tl

  aggregate TrackingAcousticTarget {
    run while ( TrackAcousticTarget )

    behavior Estimation:TrackAcousticContact {
      run in parallel

      set contactLabelSetting = AcousticTargetContactLabel
      set numberOfSamplesSetting = NumberOfPings
      set updatePeriodSetting = TrackingUpdatePeriod
      set numFixesLowPassSetting = NumberOfFixesLowPass
      set numStartingFixesToIgnoreSetting = NumberOfStartingFixesToIgnore
      set contactDepthSetting = AcousticTargetDepth
    }
  }

  aggregate UpdateCenter {
    run when (
      elapsed ( Estimation:TrackAcousticContact.range_to_contact ) < AcousticTargetContactTimeout
      and ( elapsed ( ElapsedSinceLastCenterUpdate ) >= TrackingUpdatePeriod )
    )

    assign in sequence CenterLatitude = Estimation:TrackAcousticContact.contact_latitude

    assign in sequence CenterLongitude = Estimation:TrackAcousticContact.contact_longitude

    assign in sequence ElapsedTime1 = elapsed ( ElapsedSinceLastCenterUpdate )

    syslog info "Updating. Elapsed time since last center update, CenterLatitude, CenterLongitude = "
         + ElapsedTime1~second + ", " + CenterLatitude~degree + ", " + CenterLongitude~degree

    assign in sequence ElapsedSinceLastCenterUpdate = 0 hour
  }

  aggregate SurfaceGPS {
    run when ( called )

    behavior Guidance:GoToSurface {
      run in progression

      set pitch = SurfacePitch
      set speed = SpeedSampling
    }

    readDatum {
      timeout duration=GPSTimeout {
        syslog important "GPS update timeout"
      }

      Universal:time_fix
    }
  }

  aggregate SampleAtDepthOrBetweenDepths {
    run when ( called )

    aggregate SamplingAtDepth {
      run in sequence

      break if (
        YoYoWhenSampling
        or ( isNaN ( DepthCircle ) )
      )

      assign in sequence SampleAtDepth:TargetDepth = DepthCircle

      assign in sequence SampleAtDepth:SettleTime = SettleDuration

      assign in sequence SampleAtDepth:ESPCartridgeType = CartType

      call id="SamplingAtDepth" priorityHere=false refId="SampleAtDepth"
    }

    aggregate SamplingBetweenDepths {
      run in sequence

      break if (
        not ( YoYoWhenSampling )
        or ( isNaN ( CircleYoYoMinDepthSampling ) )
        or ( isNaN ( CircleYoYoMaxDepthSampling ) )
      )

      assign in sequence Sample:ESPCartridgeType = CartType

      call id="SamplingBetweenDepths" priorityHere=false refId="Sample"
    }
  }

  aggregate SendSampleStartMessage {
    run when ( called )

    aggregate SampleStartSignal {
      run in sequence

      break if ( not ( UseOtherLRAUVSignals ) )

      behavior Sensor:SendDirect {
        run in sequence

        set destType = "modem"
        set destId = ModemIDofOtherLRAUV
        set destName = "_.sampleStart"
        set value = TrueVar
        set unit = "bool"
      }

      syslog important "Set _.sampleStart to " + TrueVar~bool
    }
  }

  aggregate SendSampleCompleteMessage {
    run when ( called )

    aggregate SampleCompleteSignal {
      run in sequence

      break if ( not ( UseOtherLRAUVSignals ) )

      behavior Sensor:SendDirect {
        run in sequence

        set destType = "modem"
        set destId = ModemIDofOtherLRAUV
        set destName = "_.sampleComplete"
        set value = TrueVar
        set unit = "bool"
      }

      syslog important "Set _.sampleComplete to " + TrueVar~bool
    }
  }

  aggregate SendSampleInfo {
    run when ( called )

    aggregate SampleInfo {
      run in sequence

      break if ( not ( SendSampleResultToWG ) )

      behavior Sensor:SendDirect {
        run in sequence

        set destType = "modem"
        set destId = ModemIDofWG
        set destName = "_.LRAUVcntSamples"
        set value = CntSamples
        set unit = "count"
      }

      # <Sensor:SendDirect>
      #                     <Sequence/>
      #                     <Setting><Sensor:SendDirect.destType/><String>modem</String></Setting>
      #                     <Setting><Sensor:SendDirect.destId/><Arg Name="ModemIDofWG"/></Setting>
      #                     <Setting><Sensor:SendDirect.destName/><String>_.ESPsampleNumber</String></Setting>
      #                     <Setting><Sensor:SendDirect.value/><Science:ESPComponent.sample_number/></Setting>
      #                     <Setting><Sensor:SendDirect.unit/><String>count</String></Setting>
      #                 </Sensor:SendDirect>

      # <Sensor:SendDirect>
      #                     <Sequence/>
      #                     <Setting><Sensor:SendDirect.destType/><String>modem</String></Setting>
      #                     <Setting><Sensor:SendDirect.destId/><Arg Name="ModemIDofWG"/></Setting>
      #                     <Setting><Sensor:SendDirect.destName/><String>_.ESPcartridgeType</String></Setting>
      #                     <Setting><Sensor:SendDirect.value/><Science:ESPComponent.cartridge/></Setting>
      #                     <Setting><Sensor:SendDirect.unit/><String>count</String></Setting>
      #                 </Sensor:SendDirect>

      behavior Sensor:SendDirect {
        run in sequence

        set destType = "modem"
        set destId = ModemIDofWG
        set destName = "_.ESPsampleVolume"
        set value = Science:ESPComponent.sampleVolume
        set unit = "milliliter"
      }

      # <Sensor:SendDirect>
      #                     <Sequence/>
      #                     <Setting><Sensor:SendDirect.destType/><String>modem</String></Setting>
      #                     <Setting><Sensor:SendDirect.destId/><Arg Name="ModemIDofWG"/></Setting>
      #                     <Setting><Sensor:SendDirect.destName/><String>_.sampleDepth</String></Setting>
      #                     <Setting><Sensor:SendDirect.value/><Universal:depth/></Setting>
      #                     <Setting><Sensor:SendDirect.unit/><String>meter</String></Setting>
      #                 </Sensor:SendDirect>

      # <Sensor:SendDirect>
      #                     <Sequence/>
      #                     <Setting><Sensor:SendDirect.destType/><String>modem</String></Setting>
      #                     <Setting><Sensor:SendDirect.destId/><Arg Name="ModemIDofWG"/></Setting>
      #                     <Setting><Sensor:SendDirect.destName/><String>_.sampleTemperature</String></Setting>
      #                     <Setting><Sensor:SendDirect.value/><Universal:sea_water_temperature/></Setting>
      #                     <Setting><Sensor:SendDirect.unit/><String>celsius</String></Setting>
      #                 </Sensor:SendDirect>

      # <Sensor:SendDirect>
      #                     <Sequence/>
      #                     <Setting><Sensor:SendDirect.destType/><String>modem</String></Setting>
      #                     <Setting><Sensor:SendDirect.destId/><Arg Name="ModemIDofWG"/></Setting>
      #                     <Setting><Sensor:SendDirect.destName/><String>_.sampleChlorophyll</String></Setting>
      #                     <Setting><Sensor:SendDirect.value/><Universal:mass_concentration_of_chlorophyll_in_sea_water/></Setting>
      #                     <Setting><Sensor:SendDirect.unit/><String>microgram_per_liter</String></Setting>
      #                 </Sensor:SendDirect>

      syslog important "CntSamples = "
           + CntSamples~count

      syslog important "Science:ESPComponent.sample_number = "
           + Science:ESPComponent.sample_number~count

      syslog important "Science:ESPComponent.cartridge = " + Science:ESPComponent.cartridge~count

      syslog important "Science:ESPComponent.sampleVolume = "
           + Science:ESPComponent.sampleVolume~milliliter

      syslog important "Universal:depth = " + Universal:depth~meter

      syslog important "Universal:sea_water_temperature = "
           + Universal:sea_water_temperature~celsius

      syslog important "Universal:mass_concentration_of_chlorophyll_in_sea_water = "
           + Universal:mass_concentration_of_chlorophyll_in_sea_water~microgram_per_liter
    }
  }

  aggregate SendTerminateMissionMessage {
    run when ( called )

    aggregate ReachDepthSendMessage {
      run in sequence

      break if ( not ( SendMessageTerminateMission ) )

      behavior Guidance:Buoyancy {
        run in parallel

        set position = Control:VerticalControl.buoyancyNeutral
      }

      behavior Guidance:SetSpeed {
        run in parallel

        set speed = SpeedSampling
      }

      aggregate ApproachDepth {
        run in sequence

        syslog important "Moving to " + SendMessageDepth~meter + "to send message."

        behavior Guidance:Pitch {
          run in sequence

          timeout duration=MaxWaitNotAchievingDepth {
            syslog important "Timed out trying to reach the send-message depth. Stopping mission."

            behavior Guidance:Execute {
              run in sequence

              set command = "stop"
            }
          }

          set depth = SendMessageDepth
        }
      }

      aggregate Msg {
        run in sequence

        behavior Guidance:Pitch {
          run in parallel

          set depth = SendMessageDepth
        }

        behavior Sensor:SendDirect {
          run in sequence

          set destType = "modem"
          set destId = ModemIDofOtherLRAUV
          set destName = "_.terminateMission"
          set value = TrueVar
          set unit = "bool"
        }

        syslog important "Set _.terminateMission to " + TrueVar~bool + ". Then wait for "
             + WaitSendMessage~minute + "."

        behavior Guidance:Wait {
          run in sequence

          set duration = WaitSendMessage
        }
      }
    }
  }

  aggregate SetSampleOptionsExceptSamplingDeps {
    run when ( called )

    aggregate SettingMaxWaitStopMissionIndividual {
      run in sequence

      break if (
        not (
          not ( isNaN ( MaxWaitStopMissionIndividual ) )
          and ( MaxWaitStopMissionIndividual > 0 hour )
        )
      )

      assign in sequence MaximumWaitStopMission = MaxWaitStopMissionIndividual
    }

    aggregate SettingMaxWaitStopMissionCommon {
      run in sequence

      break if (
        not ( isNaN ( MaxWaitStopMissionIndividual ) )
        and ( MaxWaitStopMissionIndividual > 0 hour )
      )

      assign in sequence MaximumWaitStopMission = MaxWaitStopMissionCommon
    }

    aggregate SettingMaxWaitFireEndToStartIndividual {
      run in sequence

      break if (
        not (
          not ( isNaN ( MaxWaitFireEndToStartIndividual ) )
          and ( MaxWaitFireEndToStartIndividual >= 0 hour )
        )
      )

      assign in sequence MaximumWaitFireEndToStart = MaxWaitFireEndToStartIndividual
    }

    aggregate SettingMaxWaitFireEndToStartCommon {
      run in sequence

      break if (
        not ( isNaN ( MaxWaitFireEndToStartIndividual ) )
        and ( MaxWaitFireEndToStartIndividual >= 0 hour )
      )

      assign in sequence MaximumWaitFireEndToStart = MaxWaitFireEndToStartCommon
    }

    aggregate SettingMaxWaitFireSinceFirstSampleStartIndividual {
      run in sequence

      assign in sequence MaximumWaitFireSinceFirstSampleStart = MaxWaitFireSinceFirstSampleStartIndividual
    }

    aggregate SettingDepsNotSamplingIndividual {
      run in sequence

      break if (
        not ( YoYoWhenNotSampling )
        or not (
          not ( isNaN ( CircleYoYoMinDepNotSamplingIndividual ) )
          and ( CircleYoYoMinDepNotSamplingIndividual > 0 meter )
          and ( not ( isNaN ( CircleYoYoMaxDepNotSamplingIndividual ) ) )
          and ( CircleYoYoMaxDepNotSamplingIndividual > 0 meter )
        )
      )

      assign in sequence CircleYoYoMinDepthNotSampling = CircleYoYoMinDepNotSamplingIndividual
      assign in sequence CircleYoYoMaxDepthNotSampling = CircleYoYoMaxDepNotSamplingIndividual
    }

    aggregate SettingDepsNotSamplingCommon {
      run in sequence

      break if (
        not ( YoYoWhenNotSampling )
        or (
          not ( isNaN ( CircleYoYoMinDepNotSamplingIndividual ) )
          and ( CircleYoYoMinDepNotSamplingIndividual > 0 meter )
          and ( not ( isNaN ( CircleYoYoMaxDepNotSamplingIndividual ) ) )
          and ( CircleYoYoMaxDepNotSamplingIndividual > 0 meter )
        )
      )

      assign in sequence CircleYoYoMinDepthNotSampling = CircleYoYoMinDepNotSamplingCommon
      assign in sequence CircleYoYoMaxDepthNotSampling = CircleYoYoMaxDepNotSamplingCommon
    }

    aggregate SettingSurfacingIndividual {
      run in sequence

      break if ( not ( SurfacingAfterSamplingIndividual ) )

      assign in sequence SurfaceAfterSampling = SurfacingAfterSamplingIndividual
    }

    aggregate SettingSurfacingCommon {
      run in sequence

      break if ( SurfacingAfterSamplingIndividual )

      assign in sequence SurfaceAfterSampling = SurfacingAfterSamplingCommon
    }

    aggregate SettingCartridgeTypeIndividual {
      run in sequence

      break if (
        not (
          not ( isNaN ( CartridgeTypeIndividual ) )
          and (
            ( CartridgeTypeIndividual >= 0 count )
            or ( CartridgeTypeIndividual < 0 count )
          )
        )
      )

      assign in sequence CartType = CartridgeTypeIndividual
    }

    aggregate SettingCartridgeTypeCommon {
      run in sequence

      break if (
        not ( isNaN ( CartridgeTypeIndividual ) )
        and (
          ( CartridgeTypeIndividual >= 0 count )
          or ( CartridgeTypeIndividual < 0 count )
        )
      )

      assign in sequence CartType = CartridgeTypeCommon
    }

    aggregate SettingSettle1 {
      run in sequence

      break if ( CntSamples >= 2 count )

      assign in sequence SettleDuration = Settle1
    }

    aggregate SettingSettleCommon {
      run in sequence

      break if ( CntSamples == 1 count )

      assign in sequence SettleDuration = SettleCommon
    }

    syslog important "Set CntSamples, CircleYoYoMinDepthNotSampling, CircleYoYoMaxDepthNotSampling, CartridgeType (if ESP), SettleDuration,  MaximumWaitStopMission, MaximumWaitFireEndToStart, MaximumWaitFireSinceFirstSampleStart to "
         + CntSamples~count + ", " + CircleYoYoMinDepthNotSampling~meter + ", "
         + CircleYoYoMaxDepthNotSampling~meter + ", " + CartType~count + ", " + SettleDuration~minute
         + "," + MaximumWaitStopMission~minute + "," + MaximumWaitFireEndToStart~minute + ","
         + MaximumWaitFireSinceFirstSampleStart~minute + "."
  }

  aggregate SetSampleOptionsSamplingDeps {
    run when ( called )

    aggregate SettingDepCircleToPeakDepthReportedByOtherLRAUV {
      run in sequence

      break if (
        YoYoWhenSampling
        or not (
          not ( isNaN ( OtherLRAUVReportedPeakDepth ) )
          and ( OtherLRAUVReportedPeakDepth > 0 meter )
          and (
            ( SampleChl
              and ( OtherLRAUVReportedPeakChl > ThreshChl )
            )
            or (
              SamplePlanktivoreLM
              and ( OtherLRAUVReportedPeakPlanktivoreLM > ThreshPlanktivoreLM )
            )
          )
        )
      )

      assign in sequence DepthCircle = OtherLRAUVReportedPeakDepth
    }

    aggregate SettingDepCircleIndividual {
      run in sequence

      break if (
        YoYoWhenSampling
        or not (
          not ( isNaN ( DepCircleIndividual ) )
          and ( DepCircleIndividual > 0 meter )
        )
        or (
          not ( isNaN ( OtherLRAUVReportedPeakDepth ) )
          and ( OtherLRAUVReportedPeakDepth > 0 meter )
          and (
            ( SampleChl
              and ( OtherLRAUVReportedPeakChl > ThreshChl )
            )
            or (
              SamplePlanktivoreLM
              and ( OtherLRAUVReportedPeakPlanktivoreLM > ThreshPlanktivoreLM )
            )
          )
        )
      )

      assign in sequence DepthCircle = DepCircleIndividual
    }

    aggregate SettingDepCircleCommon {
      run in sequence

      break if (
        YoYoWhenSampling
        or (
          not ( isNaN ( DepCircleIndividual ) )
          and ( DepCircleIndividual > 0 meter )
        )
        or (
          not ( isNaN ( OtherLRAUVReportedPeakDepth ) )
          and ( OtherLRAUVReportedPeakDepth > 0 meter )
          and (
            ( SampleChl
              and ( OtherLRAUVReportedPeakChl > ThreshChl )
            )
            or (
              SamplePlanktivoreLM
              and ( OtherLRAUVReportedPeakPlanktivoreLM > ThreshPlanktivoreLM )
            )
          )
        )
      )

      assign in sequence DepthCircle = DepCircleCommon
    }

    aggregate SettingDepsSamplingToPeakDepthsReportedByOtherLRAUV {
      run in sequence

      break if (
        not ( YoYoWhenSampling )
        or not (
          not ( isNaN ( OtherLRAUVReportedPeakDepth ) )
          and ( OtherLRAUVReportedPeakDepth > 0 meter )
          and ( not ( isNaN ( OtherLRAUVReportedPeakDepthPreceding ) ) )
          and ( OtherLRAUVReportedPeakDepthPreceding > 0 meter )
          and (
            ( SampleChl
              and ( OtherLRAUVReportedPeakChl > ThreshChl )
            )
            or (
              SamplePlanktivoreLM
              and ( OtherLRAUVReportedPeakPlanktivoreLM > ThreshPlanktivoreLM )
            )
          )
        )
      )

      aggregate PeakDepthPrecedingDeeperThanPeakDepth {
        run in sequence

        break if (
          OtherLRAUVReportedPeakDepth >= OtherLRAUVReportedPeakDepthPreceding
        )

        assign in sequence CircleYoYoMinDepthSampling = OtherLRAUVReportedPeakDepth
        assign in sequence CircleYoYoMaxDepthSampling = OtherLRAUVReportedPeakDepthPreceding
      }

      aggregate PeakDepthPrecedingShallowerThanPeakDepth {
        run in sequence

        break if (
          OtherLRAUVReportedPeakDepth < OtherLRAUVReportedPeakDepthPreceding
        )

        assign in sequence CircleYoYoMinDepthSampling = OtherLRAUVReportedPeakDepthPreceding
        assign in sequence CircleYoYoMaxDepthSampling = OtherLRAUVReportedPeakDepth
      }
    }

    aggregate SettingDepsSamplingIndividual {
      run in sequence

      break if (
        not ( YoYoWhenSampling )
        or not (
          not ( isNaN ( CircleYoYoMinDepSamplingIndividual ) )
          and ( CircleYoYoMinDepSamplingIndividual > 0 meter )
          and ( not ( isNaN ( CircleYoYoMaxDepSamplingIndividual ) ) )
          and ( CircleYoYoMaxDepSamplingIndividual > 0 meter )
        )
        or (
          not ( isNaN ( OtherLRAUVReportedPeakDepth ) )
          and ( OtherLRAUVReportedPeakDepth > 0 meter )
          and ( not ( isNaN ( OtherLRAUVReportedPeakDepthPreceding ) ) )
          and ( OtherLRAUVReportedPeakDepthPreceding > 0 meter )
          and (
            ( SampleChl
              and ( OtherLRAUVReportedPeakChl > ThreshChl )
            )
            or (
              SamplePlanktivoreLM
              and ( OtherLRAUVReportedPeakPlanktivoreLM > ThreshPlanktivoreLM )
            )
          )
        )
      )

      assign in sequence CircleYoYoMinDepthSampling = CircleYoYoMinDepSamplingIndividual
      assign in sequence CircleYoYoMaxDepthSampling = CircleYoYoMaxDepSamplingIndividual
    }

    aggregate SettingDepsSamplingCommon {
      run in sequence

      break if (
        not ( YoYoWhenSampling )
        or (
          not ( isNaN ( CircleYoYoMinDepSamplingIndividual ) )
          and ( CircleYoYoMinDepSamplingIndividual > 0 meter )
          and ( not ( isNaN ( CircleYoYoMaxDepSamplingIndividual ) ) )
          and ( CircleYoYoMaxDepSamplingIndividual > 0 meter )
        )
        or (
          not ( isNaN ( OtherLRAUVReportedPeakDepth ) )
          and ( OtherLRAUVReportedPeakDepth > 0 meter )
          and ( not ( isNaN ( OtherLRAUVReportedPeakDepthPreceding ) ) )
          and ( OtherLRAUVReportedPeakDepthPreceding > 0 meter )
          and (
            ( SampleChl
              and ( OtherLRAUVReportedPeakChl > ThreshChl )
            )
            or (
              SamplePlanktivoreLM
              and ( OtherLRAUVReportedPeakPlanktivoreLM > ThreshPlanktivoreLM )
            )
          )
        )
      )

      assign in sequence CircleYoYoMinDepthSampling = CircleYoYoMinDepSamplingCommon
      assign in sequence CircleYoYoMaxDepthSampling = CircleYoYoMaxDepSamplingCommon
    }

    syslog important "Set DepthCircle, CircleYoYoMinDepthSampling, CircleYoYoMaxDepthSampling to "
         + DepthCircle~meter + ", " + CircleYoYoMinDepthSampling~meter + ", "
         + CircleYoYoMaxDepthSampling~meter + "."
  }

  # Automatically restart logs

  aggregate CycleLogs {
    run in parallel

    aggregate {
      run in sequence

      behavior Guidance:Wait {
        run in sequence

        set duration = IntervalRestartLogs
      }

      syslog important "Restarting logs."

      behavior Guidance:Execute {
        run in sequence

        set command = "restart logs"
      }
    }
  }

  aggregate CheckOtherLRAUVSampleStart {
    run when (
      elapsed ( customUri "_.sampleStart" ) < ( elapsed ( OtherLRAUVSampleStartReceived ) )
    )

    # Reset ElapsedSinceMissionStartOrLastSampleStart timer for firing on maxwait.

    assign in sequence ElapsedSinceMissionStartOrLastSampleStart = 0 hour

    syslog important "Received the other LRAUV's sample start signal."

    assign in sequence OtherLRAUVSampleStartReceived = customUri "_.sampleStart"
  }

  aggregate CheckOtherLRAUVSampleComplete {
    run when (
      elapsed ( customUri "_.sampleComplete" ) < ( elapsed ( OtherLRAUVSampleCompleteReceived ) )
    )

    # Reset ElapsedSinceLastSampleEnd timer for firing on maxwait.

    assign in sequence ElapsedSinceLastSampleEnd = 0 hour

    syslog important "Received the other LRAUV's sample completed signal."

    assign in sequence OtherLRAUVSampleCompleteReceived = customUri "_.sampleComplete"
  }

  aggregate CheckOtherLRAUVReportedPeakDepth {
    run when (
      elapsed ( customUri "_.peakDepth" ) < ( elapsed ( OtherLRAUVReportedPeakDepth ) )
    )

    assign in sequence OtherLRAUVReportedPeakDepthPreceding = OtherLRAUVReportedPeakDepth

    assign in sequence OtherLRAUVReportedPeakDepth = customUri "_.peakDepth"

    syslog important "Received the peak signal and the corresponding depth reported by the other LRAUV. OtherLRAUVReportedPeakDepthPreceding, OtherLRAUVReportedPeakDepth = "
         + OtherLRAUVReportedPeakDepthPreceding~meter + " ," + OtherLRAUVReportedPeakDepth~meter + "."

    aggregate SamplingChl {
      run in sequence

      break if ( not ( SampleChl ) )

      assign in sequence OtherLRAUVReportedPeakChl = customUri "_.peakChl"

      syslog important "OtherLRAUVReportedPeakChl = "
           + OtherLRAUVReportedPeakChl~microgram_per_liter + "."
    }

    aggregate SamplingPlanktivoreLM {
      run in sequence

      break if ( not ( SamplePlanktivoreLM ) )

      assign in sequence OtherLRAUVReportedPeakPlanktivoreLM = customUri "_.peakPlanktivoreLM"

      syslog important "OtherLRAUVReportedPeakPlanktivoreLM = "
           + OtherLRAUVReportedPeakPlanktivoreLM~count_per_second + "."
    }
  }

  aggregate MissionStartComms {
    run in sequence

    break if (
      not ( NeedCommsMissionStart )
      or MissionStartCommsCompleted
    )

    syslog important "Mission start comms."

    call id="MissionStartComms" priorityHere=false refId="NeedComms"

    assign in sequence ElapsedSinceMissionStartOrLastSampleStart = 0 hour

    assign in sequence ElapsedSinceLastSampleEnd = 0 hour

    assign in sequence MissionStartCommsCompleted = true
  }

  aggregate MissionStartNoComms {
    run in sequence

    break if (
      NeedCommsMissionStart
      or MissionStartCommsCompleted
    )

    syslog important "Mission start no comms."

    assign in sequence ElapsedSinceMissionStartOrLastSampleStart = 0 hour

    assign in sequence ElapsedSinceLastSampleEnd = 0 hour

    assign in sequence MissionStartCommsCompleted = true
  }

  macro $k = 1..60 {
    aggregate SetOptionsOfSample$k {
      run when (
        not ( SampleOptionsSet )
        and ( CntSamples == $k count )
        and ( CntSamples <= NumSamplers )
        and ( not ( FlagSamplingOngoing ) )
      )

      assign in sequence MaxWaitStopMissionIndividual = MaxWaitStopMission[$k]

      assign in sequence MaxWaitFireEndToStartIndividual = MaxWaitFireEndToStart[$k]

      assign in sequence MaxWaitFireSinceFirstSampleStartIndividual = MaxWaitFireSinceFirstSampleStart[$k]

      assign in sequence DepCircleIndividual = DepCircle[$k]

      assign in sequence CircleYoYoMinDepNotSamplingIndividual = CircleYoYoMinDepNotSampling[$k]

      assign in sequence CircleYoYoMaxDepNotSamplingIndividual = CircleYoYoMaxDepNotSampling[$k]

      assign in sequence CircleYoYoMinDepSamplingIndividual = CircleYoYoMinDepSampling[$k]

      assign in sequence CircleYoYoMaxDepSamplingIndividual = CircleYoYoMaxDepSampling[$k]

      assign in sequence SurfacingAfterSamplingIndividual = SurfacingAfterSampling[$k]

      assign in sequence CartridgeTypeIndividual = CartridgeType[$k]

      call id="SetOptionsForSample$k" priorityHere=false refId="SetSampleOptionsExceptSamplingDeps"

      # The following line is needed.
      call id="SetOptionsForDepthCircle" priorityHere=false refId="SetSampleOptionsSamplingDeps"

      assign in sequence SampleOptionsSet = true
    }
  }

  aggregate CircleAndSample {
    run in sequence

    break if (
      CntSamples == ( NumSamplers + 1 count )
      or (
        ( isNaN ( DepthCircle ) )
        and (
          isNaN ( CircleYoYoMinDepthSampling )
          or isNaN ( CircleYoYoMinDepthSampling )
        )
      )
      or ( not ( MissionStartCommsCompleted ) )
    )

    behavior Guidance:Buoyancy {
      run in parallel

      set position = BuoyancyNeutral
    }

    behavior Guidance:SetSpeed {
      run in parallel

      set speed = SpeedSampling
    }

    syslog important "Circle around location " + CenterLatitude~degree + ","
         + CenterLongitude~degree + ", at radius = " + CircleRadius~meter
         + ". When sampling or not sampling, circle at sampling depth or circle-yoyo."

    aggregate Circle {
      run in sequence repeat=MaxNumCircles

      aggregate WhenSampling {
        run in sequence

        break if ( not ( FlagSamplingOngoing ) )

        aggregate CircleAtDepthWhenSampling {
          run in sequence

          break if (
            not (
              isNaN ( CircleYoYoMinDepthSampling )
              or ( isNaN ( CircleYoYoMaxDepthSampling ) )
            )
            or ( isNaN ( DepthCircle ) )
          )

          assign in sequence NeedComms:DiveInterval = NeedCommsTimeVeryLong

          behavior Guidance:Pitch {
            run in parallel

            set depth = DepthCircle
          }

          assign in parallel Control:HorizontalControl.kwpHeading = KwpHeading

          behavior Guidance:Circle {
            run in sequence

            set latitude = CenterLatitude
            set longitude = CenterLongitude
            set radius = CircleRadius
            set maxError = CircleMaxError
            set turnToPort = CircleTurnToPort
          }
        }

        aggregate CircleAndYoyoWhenSampling {
          run in sequence

          break if (
            isNaN ( CircleYoYoMinDepthSampling )
            or ( isNaN ( CircleYoYoMaxDepthSampling ) )
          )

          insert id="NeedComms" Insert/NeedComms.tl

          assign in sequence NeedComms:DiveInterval = NeedCommsTimeYoYo

          behavior Guidance:DepthEnvelope {
            run in parallel

            set minDepth = CircleYoYoMinDepthSampling
            set maxDepth = CircleYoYoMaxDepthSampling
            set downPitch = YoYoDownPitch
            set upPitch = YoYoUpPitch
          }

          behavior Guidance:AltitudeEnvelope {
            """
            Another altitude envelope for the YoYo behavior. This envelope
            should fall within the limits of the standard safety envelopes in
            Insert/StandardEnvelopes.tl in order to avoid commanding high pitch
            angles for bottom-terminated YoYos.
            """

            run in parallel

            set minAltitude = YoYoMinAltitude
            set pitch = YoYoUpPitch
          }

          behavior Guidance:YoYo {
            run in parallel

            set downPitch = YoYoDownPitch
            set upPitch = YoYoUpPitch
          }

          assign in parallel Control:HorizontalControl.kwpHeading = KwpHeading

          behavior Guidance:Circle {
            run in sequence

            set latitude = CenterLatitude
            set longitude = CenterLongitude
            set radius = CircleRadius
            set maxError = CircleMaxError
            set turnToPort = CircleTurnToPort
          }
        }
      }

      aggregate WhenNotSampling {
        run in sequence

        break if ( FlagSamplingOngoing )

        aggregate CircleAtDepthWhenNotSampling {
          run in sequence

          break if (
            not (
              isNaN ( CircleYoYoMinDepthNotSampling )
              or ( isNaN ( CircleYoYoMaxDepthNotSampling ) )
            )
            or ( isNaN ( DepthCircle ) )
          )

          behavior Guidance:Pitch {
            run in parallel

            set depth = DepthCircle
          }

          assign in parallel Control:HorizontalControl.kwpHeading = KwpHeading

          behavior Guidance:Circle {
            run in sequence

            set latitude = CenterLatitude
            set longitude = CenterLongitude
            set radius = CircleRadius
            set maxError = CircleMaxError
            set turnToPort = CircleTurnToPort
          }
        }

        aggregate CircleAndYoyoWhenNotSampling {
          run in sequence

          break if (
            isNaN ( CircleYoYoMinDepthNotSampling )
            or ( isNaN ( CircleYoYoMaxDepthNotSampling ) )
          )

          insert id="NeedComms" Insert/NeedComms.tl

          assign in sequence NeedComms:DiveInterval = NeedCommsTimeYoYo

          behavior Guidance:DepthEnvelope {
            run in parallel

            set minDepth = CircleYoYoMinDepthNotSampling
            set maxDepth = CircleYoYoMaxDepthNotSampling
            set downPitch = YoYoDownPitch
            set upPitch = YoYoUpPitch
          }

          behavior Guidance:AltitudeEnvelope {
            """
            Another altitude envelope for the YoYo behavior. This envelope
            should fall within the limits of the standard safety envelopes in
            Insert/StandardEnvelopes.tl in order to avoid commanding high pitch
            angles for bottom-terminated YoYos.
            """

            run in parallel

            set minAltitude = YoYoMinAltitude
            set pitch = YoYoUpPitch
          }

          behavior Guidance:YoYo {
            run in parallel

            set downPitch = YoYoDownPitch
            set upPitch = YoYoUpPitch
          }

          assign in parallel Control:HorizontalControl.kwpHeading = KwpHeading

          behavior Guidance:Circle {
            run in sequence

            set latitude = CenterLatitude
            set longitude = CenterLongitude
            set radius = CircleRadius
            set maxError = CircleMaxError
            set turnToPort = CircleTurnToPort
          }
        }
      }
    }

    aggregate Sampling {
      run in parallel

      aggregate NoFiringForTooLong {
        run when (
          MissionStartCommsCompleted
          and ( elapsed ( ElapsedSinceMissionStartOrLastSampleStart ) > MaximumWaitStopMission )
          and ( not ( FlagSamplingOngoing ) )
          and ( not ( StoppedForNoFiringForTooLong ) )
        )

        assign in sequence ElapsedTime1 = elapsed ( ElapsedSinceMissionStartOrLastSampleStart )

        syslog important "No firing for too long. Stopping mission. Elapsed time since start or last firing, MaxWaitStopMission, CntSamples = "
             + ElapsedTime1~minute + ", " + MaximumWaitStopMission~minute + ", " + CntSamples~count

        behavior Guidance:Execute {
          run in sequence

          set command = "stop"
        }

        assign in sequence StoppedForNoFiringForTooLong = true
      }

      aggregate FiringOnMaxWaitOrNotReceivingOtherLRAUVSampleStartFirstSample {
        run when (
          MissionStartCommsCompleted
          and ( not ( FlagSamplingOngoing ) )
          and ( CntSamples == 1 count )
          and SampleOptionsSet
          and ( not ( SampleCompleted ) )
          and (
            not ( isNaN ( DepthCircle ) )
            or (
              isNaN ( DepthCircle )
              and ( Universal:depth >= CircleYoYoMinDepthSampling )
              and ( Universal:depth <= CircleYoYoMaxDepthSampling )
            )
          )
          and (
            UseOtherLRAUVSignals
            and ( not ( OtherLRAUVSampleStartReceived ) )
            and ( elapsed ( ElapsedSinceMissionStartOrLastSampleStart ) > MaxWaitFirstSampleOtherLRAUVSampleStartNotReceived )
            or (
              UseOtherLRAUVSignals
              and ( OtherLRAUVSampleStartReceived )
              and ( elapsed ( ElapsedSinceMissionStartOrLastSampleStart ) > MaxWaitFirstSampleOtherLRAUVSampleStartReceived )
            )
            or (
              not ( UseOtherLRAUVSignals )
              and ( elapsed ( ElapsedSinceMissionStartOrLastSampleStart ) > MaxWaitFirstSampleOtherLRAUVSampleStartNotReceived )
            )
          )
        )

        call id="SetOptionsForDepthCircle" priorityHere=false refId="SetSampleOptionsSamplingDeps"

        assign in sequence OtherLRAUVReportedPeakDepth = NaN meter

        assign in sequence FiredOnMaxWait = true

        assign in sequence OtherLRAUVSampleStartReceived = false

        assign in sequence OtherLRAUVSampleCompleteReceived = false

        assign in sequence FlagSamplingOngoing = true

        assign in sequence ElapsedTime1 = elapsed ( ElapsedSinceMissionStartOrLastSampleStart )

        assign in sequence ElapsedTime2 = elapsed ( ElapsedSinceLastSampleEnd )

        syslog important "Elapsed time since mission start (= " + ElapsedTime1~minute
             + ") is longer than MaxWaitFirstSampleOtherLRAUVSampleStartNotReceived (= "
             + MaxWaitFirstSampleOtherLRAUVSampleStartNotReceived~minute
             + ") or MaxWaitFirstSampleOtherLRAUVSampleStartReceived (= "
             + MaxWaitFirstSampleOtherLRAUVSampleStartReceived~minute + "). Fire sample No."
             + CntSamples~count

        assign in sequence ElapsedSinceMissionStartOrLastSampleStart = 0 hour

        assign in sequence ElapsedSinceFirstSampleStart = 0 hour

        call id="SampleStartSignal" priorityHere=false refId="SendSampleStartMessage"

        call id="Sampling" priorityHere=false refId="SampleAtDepthOrBetweenDepths"

        call id="SampleCompleteSignal" priorityHere=false refId="SendSampleCompleteMessage"

        call id="SampleInfo" priorityHere=false refId="SendSampleInfo"

        assign in sequence ElapsedSinceLastSampleEnd = 0 hour

        syslog important "Sample No." + CntSamples~count + " completed."

        assign in sequence SampleCompleted = true

        assign in sequence SampleOptionsSet = false

        aggregate Surfacing {
          run in sequence

          break if (
            not ( SurfaceAfterSampling )
            or ( not ( SampleCompleted ) )
          )

          syslog important "After sampling, surface for GPS fix."

          call id="SurfaceGPSSampleEnd" priorityHere=false refId="SurfaceGPS"
        }

        behavior Guidance:Wait {
          run in sequence

          break if ( not ( UseOtherLRAUVSignals ) )

          set duration = WaitBeforeFiring
        }

        assign in sequence FlagSamplingOngoing = false
      }

      aggregate FiringOnMaxWaitNotFirstSample {
        run when (
          MissionStartCommsCompleted
          and ( not ( FlagSamplingOngoing ) )
          and ( CntSamples >= 2 count )
          and ( CntSamples <= NumSamplers )
          and SampleOptionsSet
          and ( not ( SampleCompleted ) )
          and (
            not ( isNaN ( DepthCircle ) )
            or (
              isNaN ( DepthCircle )
              and ( Universal:depth >= CircleYoYoMinDepthSampling )
              and ( Universal:depth <= CircleYoYoMaxDepthSampling )
            )
          )
          and (
            ( elapsed ( ElapsedSinceFirstSampleStart ) > MaximumWaitFireSinceFirstSampleStart )
            or ( elapsed ( ElapsedSinceLastSampleEnd ) > MaximumWaitFireEndToStart )
          )
        )

        call id="SetOptionsForDepthCircle" priorityHere=false refId="SetSampleOptionsSamplingDeps"

        assign in sequence OtherLRAUVReportedPeakDepth = NaN meter

        assign in sequence FiredOnMaxWait = true

        assign in sequence OtherLRAUVSampleStartReceived = false

        assign in sequence OtherLRAUVSampleCompleteReceived = false

        assign in sequence FlagSamplingOngoing = true

        assign in sequence ElapsedTime1 = elapsed ( ElapsedSinceFirstSampleStart )

        assign in sequence ElapsedTime2 = elapsed ( ElapsedSinceLastSampleEnd )

        syslog important "Elapsed time since first sample start (= " + ElapsedTime1~minute
             + ") is longer than MaximumWaitFireSinceFirstSampleStart (= "
             + MaximumWaitFireSinceFirstSampleStart~minute + "), or elapsed time since last sample end (= "
             + ElapsedTime2~minute + ") is longer than MaximumWaitFireEndToStart (= "
             + MaximumWaitFireEndToStart~minute + "). Fire sample No." + CntSamples~count

        assign in sequence ElapsedSinceMissionStartOrLastSampleStart = 0 hour

        call id="SampleStartSignal" priorityHere=false refId="SendSampleStartMessage"

        call id="Sampling" priorityHere=false refId="SampleAtDepthOrBetweenDepths"

        call id="SampleCompleteSignal" priorityHere=false refId="SendSampleCompleteMessage"

        call id="SampleInfo" priorityHere=false refId="SendSampleInfo"

        assign in sequence ElapsedSinceLastSampleEnd = 0 hour

        syslog important "Sample No." + CntSamples~count + " completed."

        assign in sequence SampleCompleted = true

        assign in sequence SampleOptionsSet = false

        aggregate Surfacing {
          run in sequence

          break if (
            not ( SurfaceAfterSampling )
            or ( not ( SampleCompleted ) )
          )

          syslog important "After sampling, surface for GPS fix."

          call id="SurfaceGPSSampleEnd" priorityHere=false refId="SurfaceGPS"
        }

        behavior Guidance:Wait {
          run in sequence

          break if ( not ( UseOtherLRAUVSignals ) )

          set duration = WaitBeforeFiring
        }

        assign in sequence FlagSamplingOngoing = false
      }

      aggregate FiringOnNotReceivingOtherLRAUVSampleStartNotFirstSample {
        run when (
          UseOtherLRAUVSignals
          and MissionStartCommsCompleted
          and ( not ( FlagSamplingOngoing ) )
          and ( CntSamples <= NumSamplers )
          and ( CntSamples >= 2 count )
          and SampleOptionsSet
          and ( not ( SampleCompleted ) )
          and (
            not ( isNaN ( DepthCircle ) )
            or (
              isNaN ( DepthCircle )
              and ( Universal:depth >= CircleYoYoMinDepthSampling )
              and ( Universal:depth <= CircleYoYoMaxDepthSampling )
            )
          )
          and ( not ( OtherLRAUVSampleStartReceived ) )
          and ( not ( FiredOnMaxWait ) )
          and ( not ( FiredOnReceivingOtherLRAUVSampleComplete ) )
        )

        call id="SetOptionsForDepthCircle" priorityHere=false refId="SetSampleOptionsSamplingDeps"

        assign in sequence OtherLRAUVReportedPeakDepth = NaN meter

        assign in sequence OtherLRAUVSampleStartReceived = false

        assign in sequence OtherLRAUVSampleCompleteReceived = false

        assign in sequence FlagSamplingOngoing = true

        syslog important "Not receiving other LRAUV sample start. Fire sample No."
             + CntSamples~count + "."

        call id="SampleStartSignal" priorityHere=false refId="SendSampleStartMessage"

        call id="Sampling" priorityHere=false refId="SampleAtDepthOrBetweenDepths"

        call id="SampleCompleteSignal" priorityHere=false refId="SendSampleCompleteMessage"

        call id="SampleInfo" priorityHere=false refId="SendSampleInfo"

        assign in sequence ElapsedSinceLastSampleEnd = 0 hour

        syslog important "Sample No." + CntSamples~count + " completed."

        assign in sequence SampleCompleted = true

        assign in sequence SampleOptionsSet = false

        behavior Guidance:Wait {
          run in sequence

          set duration = WaitBeforeFiring
        }

        assign in sequence FlagSamplingOngoing = false
      }

      aggregate FiringOnReceivingOtherLRAUVSampleComplete {
        run when (
          UseOtherLRAUVSignals
          and MissionStartCommsCompleted
          and ( not ( FlagSamplingOngoing ) )
          and ( CntSamples <= NumSamplers )
          and SampleOptionsSet
          and ( not ( SampleCompleted ) )
          and (
            not ( isNaN ( DepthCircle ) )
            or (
              isNaN ( DepthCircle )
              and ( Universal:depth >= CircleYoYoMinDepthSampling )
              and ( Universal:depth <= CircleYoYoMaxDepthSampling )
            )
          )
          and OtherLRAUVSampleStartReceived
          and OtherLRAUVSampleCompleteReceived
          and ( elapsed ( OtherLRAUVSampleStartReceived ) > ( elapsed ( OtherLRAUVSampleCompleteReceived ) ) )
        )

        call id="SetOptionsForDepthCircle" priorityHere=false refId="SetSampleOptionsSamplingDeps"

        assign in sequence OtherLRAUVReportedPeakDepth = NaN meter

        assign in sequence FiredOnReceivingOtherLRAUVSampleComplete = true

        assign in sequence OtherLRAUVSampleStartReceived = false

        assign in sequence OtherLRAUVSampleCompleteReceived = false

        assign in sequence FlagSamplingOngoing = true

        syslog important "Other LRAUV sample completed. Firing sample No." + CntSamples~count + "."

        aggregate FirstSample {
          run in sequence

          break if ( CntSamples >= 2 count )

          assign in sequence ElapsedSinceFirstSampleStart = 0 hour
        }

        call id="SampleStartSignal" priorityHere=false refId="SendSampleStartMessage"

        call id="Sampling" priorityHere=false refId="SampleAtDepthOrBetweenDepths"

        call id="SampleCompleteSignal" priorityHere=false refId="SendSampleCompleteMessage"

        call id="SampleInfo" priorityHere=false refId="SendSampleInfo"

        assign in sequence ElapsedSinceLastSampleEnd = 0 hour

        syslog important "Sample No." + CntSamples~count + " completed."

        assign in sequence SampleCompleted = true

        assign in sequence SampleOptionsSet = false

        behavior Guidance:Wait {
          run in sequence

          set duration = WaitBeforeFiring
        }

        assign in sequence FlagSamplingOngoing = false
      }

      aggregate SendTerminateMissionMsg {
        run when (
          SendMessageTerminateMission
          and SampleCompleted
          and ( CntSamples == NumSamplers )
        )

        call id="TerminateMissionMessage" priorityHere=false refId="SendTerminateMissionMessage"

        assign in sequence TerminateMissionMessageSent = true
      }

      aggregate IncrementSampleCounter {
        run when (
          SampleCompleted
          and (
            ( not ( SendMessageTerminateMission ) )
            or ( not ( CntSamples == NumSamplers ) )
            or (
              SendMessageTerminateMission
              and ( CntSamples == NumSamplers )
              and TerminateMissionMessageSent
            )
          )
        )

        assign in sequence SampleCompleted = false

        assign in sequence CntSamples = CntSamples + 1 count

        assign in sequence FiredOnMaxWait = false

        assign in sequence FiredOnReceivingOtherLRAUVSampleComplete = false
      }
    }
  }
}