Insert/Science.tl

#  Copyright (c) 2024 MBARI
#  MBARI Proprietary Information. Confidential. All Rights Reserved
#  Unauthorized copying or distribution of this file via any medium is strictly
#  prohibited.
#
#  WARNING - This file contains information whose export is restricted by the
#  Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
#  amended. Violations of these export laws are subject to severe civil and/or
#  criminal penalties.

aggregate Science {
  arguments {
    PeakDetectChlActive = false
      """
      Turns on peak detection of Cholorphyll.
      """

    PeakDepthAvgProfilesChlActive = false
      """
      Turns on reporting of cholorphyll peak depth averaged over a number of yo-yo profiles.
      """

    EdgeDetectChlActive = false
      """
      Turns on edge detection of Cholorphyll.
      """

    TimeWindowPeakReport = NaN minute
      """
      If greater than zero, report a peak every window. If NaN or zero, this
      variable is ignored.
      """

    HighestChlPeakReportActive = false
      """
      Turns on reporting of the highest peak value of chlorophyll on yo-yo
      profiles in a horizontal sliding window (of length
      numProfilesSlidingwindow)
      """

    HighestSaltPeakReportActive = false
      """
      Turns on reporting of the highest peak value of salinity on yo-yo
      profiles in a horizontal sliding window (of length
      numProfilesSlidingwindow)
      """

    HighestOilPeakReportActive = false
      """
      Turns on reporting of the highest peak value of oil on yo-yo profiles in
      a horizontal sliding window (of length numProfilesSlidingwindow)
      """

    PatchTracking = false
      """
      If tracking a patch
      """

    FilterWidthHorizontal = 3 count
      """
      Width of boxcar filter applied to yoyo-wise chl peaks to pick out the
      highest peak.
      """

    NumProfilesSlidingwindow = 100 count
      """
      Length of horizontal sliding window. The highest yoyo-wise chl peak
      (after low-pass filtering by a filter of length FilterWidthHorizontal)
      within this window.
      """

    OffPeakFractionHorizontal = 80 percent
      """
      When filtered horizontal value is this fraction of the peak, consider it
      outside the patch.
      """

    PeakDetectNO3Active = false
      """
      Turns on peak detection of Nitrate (and turns on ISUS).
      """

    PeakDetectOilActive = false
      """
      Turns on peak detection of Dissolved Oil.
      """

    PeakDetectFDOMActive = false
      """
      Turns on peak detection of
      concentration_of_colored_dissolved_organic_matter_in_sea_water from FDOM
      sensor.
      """

    PeakDetectSalinityActive = false
      """
      Turns on peak detection of salinity.
      """

    PeakDetectPlanktivoreLMavgROIActive = false
      """
      Turns on peak detection of PlanktivoreLMavgROI.
      """

    PeakDepthAvgProfilesPlanktivoreLMavgROIActive = false
      """
      Turns on reporting of LMavgROI peak depth averaged over a number of yo-yo profiles.
      """

    EdgeDetectPlanktivoreLMavgROIActive = false
      """
      Turns on edge detection of PlanktivoreLMavgROI.
      """

    PeakDetectPlanktivoreHMavgROIActive = false
      """
      Turns on peak detection of PlanktivoreHMavgROI.
      """

    EdgeDetectPlanktivoreHMavgROIActive = false
      """
      Turns on edge detection of PlanktivoreHMavgROI.
      """

    PeakDetectPlanktivoreDiatomsActive = false
      """
      Turns on peak detection of PlanktivoreDiatoms.
      """

    EdgeDetectPlanktivoreDiatomsActive = false
      """
      Turns on edge detection of PlanktivoreDiatoms.
      """

    PeakDetectPlanktivoreDinoflagellatesActive = false
      """
      Turns on peak detection of PlanktivoreDinoflagellates.
      """

    EdgeDetectPlanktivoreDinoflagellatesActive = false
      """
      Turns on edge detection of PlanktivoreDinoflagellates.
      """

    UpwardDerivativeOfTemperatureActive = false
      """
      Turns on seawater temperature derivative.
      """

    EnabledAanderaaO2 = Science:Aanderaa_O2.loadAtStartup
      """
      Automatically set to True if the Aanderaa O2 sensor is installed. Set to
      false to disable reading Aandera O2.
      """

    EnabledNeilBrown = Science:CTD_NeilBrown.loadAtStartup
      """
      Automatically set to true if the Neil Brown CTD is enabled. Set to false
      to disable reading from the Neil Brown.
      """

    EnabledRBRTridente = Science:RBRTridente.loadAtStartup
      """
      Automatically set to true if the RBR Tridente is enabled. Set to false
      to disable reading from the Tridente.
      """

    EnabledSeabird = Science:CTD_Seabird.loadAtStartup
      """
      Automatically set to true if the CTD is enabled. Set to false to disable
      reading from the CTD.
      """

    EnabledWetLabsBB2FL = Science:WetLabsBB2FL.loadAtStartup
      """
      Automatically set to true if the the WetLabs BB2FL is enabled. Set to
      false to disable the WetLabs BB2FL.
      """

    EnabledWetLabsSeaOWL_UV_A = Science:WetLabsSeaOWL_UV_A.loadAtStartup
      """
      Automatically set to true if the the WetLabs SeaOWL UV-A is enabled. Set
      to false to disable the WetLabs SeaOWL UV-A.
      """

    EnabledWetLabsUBAT = Science:WetLabsUBAT.loadAtStartup
      """
      Automatically set to true if the the WetLabs UBAT is enabled. Set to
      false to disable the WetLabs UBAT.
      """

    LowPassWindowLength = 20 count
      """
      Low-pass window length (based on depth sensor sampling interval 0.4
      second) for low-pass filtering.
      """

    MedianFilterLen = 5 count
      """
      Median filter length (only for chlorophyll fluorescence which tends to
      have spikes)
      """

    ShallowBound = NaN meter
      """
      Shallow depth bound for detecting any peak or edge on each descent or ascent
      profile.
      """

    DeepBound = NaN meter
      """
      Deep depth bound for detecting any peak or edge on each descent or ascent
      profile.
      """

    DeepThreshValidLeg = NaN meter
      """
      Flip-to-ascent depth needs to be deeper than this threshold to be considered a valid leg for peak reporting.
      """

    DepChangeThreshForAttitudeFlip = 2.0 meter
      """
      Depth change threshold for determining vehicle attitude flip.
      """

    OffPeakFractionVerticalAscent = NaN percent
      """
      Off-peak fraction for defining the edge of a vertical layer when vehicle is on ascent.
      """

    OffPeakFractionVerticalDescent = NaN percent
      """
      Off-peak fraction for defining the edge of a vertical layer when vehicle is on descent.
      """

    ChlPeakThresh = 0 microgram_per_liter
      """
      In vertical-dimension edge detection, threshold for qualifying as an peak.
      """

    NumberOfLayers = 1 count
      """
      Expected number of high-signal layers.
      """

    ChlThreshTriggerActive = false
      """
      Turns on chlorophyll threshold trigger.
      """

    ChlLowerThresh = NaN microgram_per_liter
      """
      Used only when ChlThreshTriggerActive is True. Triggered when
      chlorophyll falls in [ChlLowerThresh ChlUpperThresh]. ChlLowerThresh is
      ignored if NaN.
      """

    ChlUpperThresh = NaN microgram_per_liter
      """
      Used only when ChlThreshTriggerActive is True. Triggered when
      chlorophyll falls in [ChlLowerThresh ChlUpperThresh]. ChlUpperThresh is
      ignored if NaN.
      """

    NumProfilesThresh = 5 count
      """
      Used only when ChlThreshTriggerActive is True. Triggered when
      chlorophyll falls in [lowerThreshold upperThreshold] on
      numProfilesThreshold consecutive profiles.
      """

    PlanktivoreLMavgROIPeakThresh = 0 count_per_second
      """
      In vertical-dimension edge detection, threshold for qualifying as an peak.
      """

    PlanktivoreHMavgROIPeakThresh = 0 count_per_second
      """
      In vertical-dimension edge detection, threshold for qualifying as an peak.
      """

    PlanktivoreDiatomsPeakThresh = 0 count_per_milliliter
      """
      In vertical-dimension edge detection, threshold for qualifying as an peak.
      """

    PlanktivoreDinoflagellatesPeakThresh = 0 count_per_milliliter
      """
      In vertical-dimension edge detection, threshold for qualifying as an peak.
      """
  }

  output {
    GoDown = true

    PeakChl = NaN microgram_per_liter

    PeakChlDepth = NaN meter

    PeakChlTemperature = NaN celsius

    PeakChlLatitude = NaN degree

    PeakChlLongitude = NaN degree

    PeakChlAvgProfiles = NaN microgram_per_liter

    PeakChlDepthAvgProfiles = NaN meter

    EdgeChl = NaN microgram_per_liter

    EdgeChlDepth = NaN meter

    EdgeChlTemperature = NaN celsius

    EdgeChlLatitude = NaN degree

    EdgeChlLongitude = NaN degree

    PeakNO3 = NaN micromole_per_liter

    PeakNO3Depth = NaN meter

    PeakNO3Latitude = NaN degree

    PeakNO3Longitude = NaN degree

    PeakOil = NaN kilogram_per_cubic_meter

    PeakOilDepth = NaN meter

    PeakOilLatitude = NaN degree

    PeakOilLongitude = NaN degree

    PeakFDOM = NaN part_per_billion

    PeakFDOMDepth = NaN meter

    PeakFDOMTemperature = NaN celsius

    PeakFDOMLatitude = NaN degree

    PeakFDOMLongitude = NaN degree

    PeakSalt = NaN psu

    PeakSaltDepth = NaN meter

    PeakSaltTemperature = NaN celsius

    PeakSaltLatitude = NaN degree

    PeakSaltLongitude = NaN degree

    PeakPlanktivoreLMavgROI = NaN count_per_second

    PeakPlanktivoreLMavgROIDepth = NaN meter

    PeakPlanktivoreLMavgROITemperature = NaN celsius

    PeakPlanktivoreLMavgROILatitude = NaN degree

    PeakPlanktivoreLMavgROILongitude = NaN degree

    PeakPlanktivoreLMavgROIAvgProfiles = NaN count_per_second

    PeakPlanktivoreLMavgROIDepthAvgProfiles = NaN meter

    EdgePlanktivoreLMavgROI = NaN count_per_second

    EdgePlanktivoreLMavgROIDepth = NaN meter

    EdgePlanktivoreLMavgROITemperature = NaN celsius

    EdgePlanktivoreLMavgROILatitude = NaN degree

    EdgePlanktivoreLMavgROILongitude = NaN degree

    PeakPlanktivoreHMavgROI = NaN count_per_second

    PeakPlanktivoreHMavgROIDepth = NaN meter

    PeakPlanktivoreHMavgROITemperature = NaN celsius

    PeakPlanktivoreHMavgROILatitude = NaN degree

    PeakPlanktivoreHMavgROILongitude = NaN degree

    EdgePlanktivoreHMavgROI = NaN count_per_second

    EdgePlanktivoreHMavgROIDepth = NaN meter

    EdgePlanktivoreHMavgROITemperature = NaN celsius

    EdgePlanktivoreHMavgROILatitude = NaN degree

    EdgePlanktivoreHMavgROILongitude = NaN degree

    PeakPlanktivoreDiatoms = NaN count_per_milliliter

    PeakPlanktivoreDiatomsDepth = NaN meter

    PeakPlanktivoreDiatomsTemperature = NaN celsius

    PeakPlanktivoreDiatomsLatitude = NaN degree

    PeakPlanktivoreDiatomsLongitude = NaN degree

    EdgePlanktivoreDiatoms = NaN count_per_milliliter

    EdgePlanktivoreDiatomsDepth = NaN meter

    EdgePlanktivoreDiatomsTemperature = NaN celsius

    EdgePlanktivoreDiatomsLatitude = NaN degree

    EdgePlanktivoreDiatomsLongitude = NaN degree

    PeakPlanktivoreDinoflagellates = NaN count_per_milliliter

    PeakPlanktivoreDinoflagellatesDepth = NaN meter

    PeakPlanktivoreDinoflagellatesTemperature = NaN celsius

    PeakPlanktivoreDinoflagellatesLatitude = NaN degree

    PeakPlanktivoreDinoflagellatesLongitude = NaN degree

    EdgePlanktivoreDinoflagellates = NaN count_per_milliliter

    EdgePlanktivoreDinoflagellatesDepth = NaN meter

    EdgePlanktivoreDinoflagellatesTemperature = NaN celsius

    EdgePlanktivoreDinoflagellatesLatitude = NaN degree

    EdgePlanktivoreDinoflagellatesLongitude = NaN degree

    PatchChl = NaN microgram_per_liter

    PatchChlDepth = NaN meter

    PatchChlLatitude = NaN degree

    PatchChlLongitude = NaN degree

    PatchChlDistance = NaN meter

    PatchSalt = NaN psu

    PatchSaltDepth = NaN meter

    PatchSaltLatitude = NaN degree

    PatchSaltLongitude = NaN degree

    PatchSaltDistance = NaN meter

    PatchOil = NaN psu

    PatchOilDepth = NaN meter

    PatchOilLatitude = NaN degree

    PatchOilLongitude = NaN degree

    PatchOilDistance = NaN meter

    TriggeredOnChl = false

    ChlTriggering = NaN microgram_per_liter
  }

  run in parallel

  readData strategy="MinError" {
    while ( EnabledAanderaaO2 )

    Universal:mass_concentration_of_oxygen_in_sea_water
  }

  readData strategy="MinError" {
    while (
      EnabledNeilBrown
      or EnabledSeabird
    )

    Universal:sea_water_temperature
    Universal:sea_water_salinity
  }

  readData strategy="MinError" {
    while ( EnabledSeabird )

    Science:CTD_Seabird.sea_water_temperature
    Science:CTD_Seabird.sea_water_salinity
  }

  readData strategy="MinError" {
    while (
      ( EnabledNeilBrown
        or EnabledSeabird
      )
      and UpwardDerivativeOfTemperatureActive
    )

    Universal:upward_derivative_of_sea_water_temperature
  }

  readData strategy="MinError" {
    while (
      EnabledWetLabsBB2FL
      or EnabledRBRTridente
      or PeakDetectChlActive
    )

    Universal:mass_concentration_of_chlorophyll_in_sea_water
  }

  readData strategy="MinError" {
    while ( EnabledWetLabsUBAT )

    Science:WetLabsUBAT.average_bioluminescence
  }

  readData id="Read_Oil" strategy="MinError" {
    while (
      EnabledWetLabsSeaOWL_UV_A
      or PeakDetectOilActive
    )

    Universal:mass_concentration_of_petroleum_hydrocarbons_in_sea_water
  }

  aggregate OceanCurrent {
    run in sequence

    behavior Estimation:CurrentEstimator {
      run in parallel
    }
  }

  aggregate PeakDetectChl {
    run while ( PeakDetectChlActive )

    # In "run while", the behavior's initialize() functions runs on init, but the redefinearg (in the mission that calls Science.tl) doesn't happen until the next cycle. The following line is a work-around to ensure redefinearg (in the mission that calls Science.tl) is taken by the behavior.. Don't delete.
    syslog debug "PeakDetectVsDepth"

    behavior Trigger:PeakDetectVsDepth {
      run in sequence

      set detect = Universal:mass_concentration_of_chlorophyll_in_sea_water
      set timeWindowPeakReport = TimeWindowPeakReport
      set windowLength = LowPassWindowLength
      set medianFilterLength = MedianFilterLen
      set shallowBound = ShallowBound
      set deepBound = DeepBound
      set deepThreshValidLeg = DeepThreshValidLeg
      set depthChangeThresh = DepChangeThreshForAttitudeFlip
      outputArg PeakChl = peakDetect
      outputArg PeakChlDepth = peakDepth
      outputArg PeakChlTemperature = peakTemperature
      outputArg PeakChlLatitude = peakLatitude
      outputArg PeakChlLongitude = peakLongitude
    }

    #debug
    #syslog info "PeakChl = " + PeakChl~microgram_per_liter + ". PeakChlDepth = " + PeakChlDepth~meter

    sendData service=express (
      PeakChl,
      PeakChlDepth
    )

    aggregate SyslogSendDataPeakDepthAvgProfilesChl {
      run in sequence

      break if ( not ( PeakDepthAvgProfilesChlActive ) )

      syslog info "PeakChlAvgProfiles = " + PeakChlAvgProfiles~microgram_per_liter
           + ". PeakChlDepthAvgProfiles = " + PeakChlDepthAvgProfiles~meter

      sendData service=express (
        PeakChlAvgProfiles,
        PeakChlDepthAvgProfiles
      )
    }
  }

  aggregate EdgeDetectChl {
    run while ( EdgeDetectChlActive )

    # The following line is a work-around to ensure redefinearg (in the mission that calls Science.tl) is taken by the behavior. Don't delete.
    syslog debug "EdgeDetectVsDepth"

    behavior Trigger:EdgeDetectVsDepth {
      run in sequence

      set detect = Universal:mass_concentration_of_chlorophyll_in_sea_water
      set windowLength = LowPassWindowLength
      set medianFilterLength = MedianFilterLen
      set shallowBound = ShallowBound
      set deepBound = DeepBound
      set offpeakFractionAscent = OffPeakFractionVerticalAscent
      set offpeakFractionDescent = OffPeakFractionVerticalDescent
      set depthChangeThresh = DepChangeThreshForAttitudeFlip
      set peakThresh = ChlPeakThresh
      set numLayers = NumberOfLayers
      outputArg GoDown = goDown
      outputArg PeakChl = peakDetect
      outputArg PeakChlDepth = peakDepth
      outputArg PeakChlTemperature = peakTemperature
      outputArg PeakChlLatitude = peakLatitude
      outputArg PeakChlLongitude = peakLongitude
      outputArg EdgeChl = edgeDetect
      outputArg EdgeChlDepth = edgeDepth
      outputArg EdgeChlTemperature = edgeTemperature
      outputArg EdgeChlLatitude = edgeLatitude
      outputArg EdgeChlLongitude = edgeLongitude
    }

    syslog info "GoDown, ChlPeakThresh, PeakChl, PeakChlDepth, EdgeChl, EdgeChlDepth = "
         + GoDown~bool + ", " + ChlPeakThresh~microgram_per_liter + ", " + PeakChl~microgram_per_liter
         + ", " + PeakChlDepth~meter + ", " + EdgeChl~microgram_per_liter + ", " + EdgeChlDepth~meter

    sendData service=express (
      PeakChl,
      PeakChlDepth,
      EdgeChl,
      EdgeChlDepth
    )
  }

  aggregate HighestChlPeakReport {
    run while ( HighestChlPeakReportActive )

    behavior Trigger:PeakDetectHorizontal {
      run in sequence

      set detectFrom = PeakChl
      set depthFrom = PeakChlDepth
      set latitudeFrom = PeakChlLatitude
      set longitudeFrom = PeakChlLongitude
      set patchTracking = PatchTracking
      set filterWidth = FilterWidthHorizontal
      set numProfilesSlidingwindow = NumProfilesSlidingwindow
      set offPeakFraction = OffPeakFractionHorizontal
      outputArg PatchChl = peakDetect
      outputArg PatchChlDepth = peakDepth
      outputArg PatchChlLatitude = peakLatitude
      outputArg PatchChlLongitude = peakLongitude
      outputArg PatchChlDistance = peakDistance
    }
  }

  aggregate PeakDepthAvgProfilesChl {
    run while ( PeakDepthAvgProfilesChlActive )

    # In "run while", the behavior's initialize() functions runs on init, but the redefinearg (in the mission that calls Science.tl) doesn't happen until the next cycle. The following line is a work-around to ensure redefinearg (in the mission that calls Science.tl) is taken by the behavior.. Don't delete.
    syslog debug "PeakDetectHorizontal"

    behavior Trigger:PeakDetectHorizontal {
      run in sequence

      # Set patchTracking to false because the purpose here is not for patch tracking but for reporting peak depth etc. at every attitude flip (ascent to descent or conversely) on yo-yo profiles. See PeakDetectHorizontal.cpp.
      set patchTracking = false
      set detectFrom = PeakChl
      set depthFrom = PeakChlDepth
      set latitudeFrom = PeakChlLatitude
      set longitudeFrom = PeakChlLongitude
      set filterWidth = FilterWidthHorizontal
      outputArg PeakChlAvgProfiles = peakDetect
      outputArg PeakChlDepthAvgProfiles = peakDepth
    }
  }

  aggregate PeakDetectNO3 {
    run while ( PeakDetectNO3Active )

    # The following line is a work-around to ensure redefinearg (in the mission that calls Science.tl) is taken by the behavior. Don't delete.
    syslog debug "PeakDetectVsDepth"

    behavior Trigger:PeakDetectVsDepth {
      run in sequence

      set detect = Universal:mole_concentration_of_nitrate_in_sea_water
      set timeWindowPeakReport = TimeWindowPeakReport
      set windowLength = LowPassWindowLength
      set shallowBound = ShallowBound
      set deepBound = DeepBound
      outputArg PeakNO3 = peakDetect
      outputArg PeakNO3Depth = peakDepth
      outputArg PeakNO3Latitude = peakLatitude
      outputArg PeakNO3Longitude = peakLongitude
    }

    sendData service=express (
      PeakNO3,
      PeakNO3Depth
    )
  }

  aggregate PeakDetectOil {
    run while ( PeakDetectOilActive )

    # The following line is a work-around to ensure redefinearg (in the mission that calls Science.tl) is taken by the behavior. Don't delete.
    syslog debug "PeakDetectVsDepth"

    behavior Trigger:PeakDetectVsDepth {
      run in sequence

      set detect = Universal:mass_concentration_of_petroleum_hydrocarbons_in_sea_water
      set timeWindowPeakReport = TimeWindowPeakReport
      set windowLength = LowPassWindowLength
      set shallowBound = ShallowBound
      set deepBound = DeepBound
      outputArg PeakOil = peakDetect
      outputArg PeakOilDepth = peakDepth
      outputArg PeakOilLatitude = peakLatitude
      outputArg PeakOilLongitude = peakLongitude
    }

    # debug
    #         <Syslog Severity="Important">PeakOil, PeakOilDepth, PeakOilTemperature, PeakOilLatitude, PeakOilLongitude = <Arg Name="PeakOil"/><Units:kilogram_per_cubic_meter/>, <Arg Name="PeakOilDepth"/><Units:meter/>, <Arg Name="PeakOilTemperature"/><Units:celsius/>, <Arg Name="PeakOilLatitude"/><Units:degree/>, <Arg Name="PeakOilLongitude"/><Units:degree/></Syslog>

    sendData service=express (
      PeakOil,
      PeakOilDepth
    )
  }

  aggregate HighestOilPeakReport {
    run while ( HighestOilPeakReportActive )

    behavior Trigger:PeakDetectHorizontal {
      run in sequence

      set detectFrom = PeakOil
      set depthFrom = PeakOilDepth
      set latitudeFrom = PeakOilLatitude
      set longitudeFrom = PeakOilLongitude
      set patchTracking = PatchTracking
      set filterWidth = FilterWidthHorizontal
      set numProfilesSlidingwindow = NumProfilesSlidingwindow
      set offPeakFraction = OffPeakFractionHorizontal
      outputArg PatchOil = peakDetect
      outputArg PatchOilDepth = peakDepth
      outputArg PatchOilLatitude = peakLatitude
      outputArg PatchOilLongitude = peakLongitude
      outputArg PatchOilDistance = peakDistance
    }
  }

  aggregate PeakDetectFDOM {
    run while ( PeakDetectFDOMActive )

    # The following line is a work-around to ensure redefinearg (in the mission that calls Science.tl) is taken by the behavior. Don't delete.
    syslog debug "PeakDetectVsDepth"

    behavior Trigger:PeakDetectVsDepth {
      run in sequence

      set detect = Universal:concentration_of_colored_dissolved_organic_matter_in_sea_water
      set timeWindowPeakReport = TimeWindowPeakReport
      set windowLength = LowPassWindowLength
      set shallowBound = ShallowBound
      set deepBound = DeepBound
      outputArg PeakFDOM = peakDetect
      outputArg PeakFDOMDepth = peakDepth
      outputArg PeakFDOMTemperature = peakTemperature
      outputArg PeakFDOMLatitude = peakLatitude
      outputArg PeakFDOMLongitude = peakLongitude
    }

    sendData service=express (
      PeakFDOM,
      PeakFDOMDepth
    )
  }

  aggregate PeakDetectSalinity {
    run while ( PeakDetectSalinityActive )

    # The following line is a work-around to ensure redefinearg (in the mission that calls Science.tl) is taken by the behavior. Don't delete.
    syslog debug "PeakDetectVsDepth"

    behavior Trigger:PeakDetectVsDepth {
      run in sequence

      set detect = Universal:sea_water_salinity
      set timeWindowPeakReport = TimeWindowPeakReport
      set windowLength = LowPassWindowLength
      set medianFilterLength = MedianFilterLen
      set shallowBound = ShallowBound
      set deepBound = DeepBound
      set depthChangeThresh = DepChangeThreshForAttitudeFlip
      outputArg PeakSalt = peakDetect
      outputArg PeakSaltDepth = peakDepth
      outputArg PeakSaltTemperature = peakTemperature
      outputArg PeakSaltLatitude = peakLatitude
      outputArg PeakSaltLongitude = peakLongitude
    }

    # debug
    #         <Syslog Severity="Important">PeakSalt, PeakSaltDepth, PeakSaltTemperature, PeakSaltLatitude, PeakSaltLongitude = <Arg Name="PeakSalt"/><Units:psu/>, <Arg Name="PeakSaltDepth"/><Units:meter/>, <Arg Name="PeakSaltTemperature"/><Units:celsius/>, <Arg Name="PeakSaltLatitude"/><Units:degree/>, <Arg Name="PeakSaltLongitude"/><Units:degree/></Syslog>

    sendData service=express (
      PeakSalt,
      PeakSaltDepth
    )
  }

  aggregate HighestSaltPeakReport {
    run while ( HighestSaltPeakReportActive )

    behavior Trigger:PeakDetectHorizontal {
      run in sequence

      set detectFrom = PeakSalt
      set depthFrom = PeakSaltDepth
      set latitudeFrom = PeakSaltLatitude
      set longitudeFrom = PeakSaltLongitude
      set patchTracking = PatchTracking
      set filterWidth = FilterWidthHorizontal
      set numProfilesSlidingwindow = NumProfilesSlidingwindow
      set offPeakFraction = OffPeakFractionHorizontal
      outputArg PatchSalt = peakDetect
      outputArg PatchSaltDepth = peakDepth
      outputArg PatchSaltLatitude = peakLatitude
      outputArg PatchSaltLongitude = peakLongitude
      outputArg PatchSaltDistance = peakDistance
    }
  }

  aggregate PeakDetectPlanktivoreLMavgROI {
    run while ( PeakDetectPlanktivoreLMavgROIActive )

    # The following line is a work-around to ensure redefinearg (in the mission that calls Science.tl) is taken by the behavior. Don't delete.
    syslog debug "PeakDetectVsDepth"

    behavior Trigger:PeakDetectVsDepth {
      run in sequence

      set detect = "_.planktivore_LM_AvgRois"
      set timeWindowPeakReport = TimeWindowPeakReport
      set windowLength = LowPassWindowLength
      set medianFilterLength = MedianFilterLen
      set shallowBound = ShallowBound
      set deepBound = DeepBound
      set depthChangeThresh = DepChangeThreshForAttitudeFlip
      outputArg PeakPlanktivoreLMavgROI = peakDetect
      outputArg PeakPlanktivoreLMavgROIDepth = peakDepth
      outputArg PeakPlanktivoreLMavgROITemperature = peakTemperature
      outputArg PeakPlanktivoreLMavgROILatitude = peakLatitude
      outputArg PeakPlanktivoreLMavgROILongitude = peakLongitude
    }

    sendData service=express (
      PeakPlanktivoreLMavgROI,
      PeakPlanktivoreLMavgROIDepth
    )

    aggregate SyslogSendDataPeakDepthAvgProfilesPlanktivoreLMavgROI {
      run in sequence

      break if (
        not ( PeakDepthAvgProfilesPlanktivoreLMavgROIActive )
      )

      syslog info "PeakPlanktivoreLMavgROIAvgProfiles = "
           + PeakPlanktivoreLMavgROIAvgProfiles~count_per_second
           + ". PeakPlanktivoreLMavgROIDepthAvgProfiles = " + PeakPlanktivoreLMavgROIDepthAvgProfiles~meter

      sendData service=express (
        PeakPlanktivoreLMavgROIAvgProfiles,
        PeakPlanktivoreLMavgROIDepthAvgProfiles
      )
    }
  }

  aggregate EdgeDetectPlanktivoreLMavgROI {
    run while ( EdgeDetectPlanktivoreLMavgROIActive )

    # The following line is a work-around to ensure redefinearg (in the mission that calls Science.tl) is taken by the behavior. Don't delete.
    syslog debug "EdgeDetectVsDepth"

    behavior Trigger:EdgeDetectVsDepth {
      run in sequence

      set detect = "_.planktivore_LM_AvgRois"
      set windowLength = LowPassWindowLength
      set medianFilterLength = MedianFilterLen
      set shallowBound = ShallowBound
      set deepBound = DeepBound
      set offpeakFractionAscent = OffPeakFractionVerticalAscent
      set offpeakFractionDescent = OffPeakFractionVerticalDescent
      set depthChangeThresh = DepChangeThreshForAttitudeFlip
      set peakThresh = PlanktivoreLMavgROIPeakThresh
      set numLayers = NumberOfLayers
      outputArg GoDown = goDown
      outputArg PeakPlanktivoreLMavgROI = peakDetect
      outputArg PeakPlanktivoreLMavgROIDepth = peakDepth
      outputArg PeakPlanktivoreLMavgROITemperature = peakTemperature
      outputArg PeakPlanktivoreLMavgROILatitude = peakLatitude
      outputArg PeakPlanktivoreLMavgROILongitude = peakLongitude
      outputArg EdgePlanktivoreLMavgROI = edgeDetect
      outputArg EdgePlanktivoreLMavgROIDepth = edgeDepth
      outputArg EdgePlanktivoreLMavgROITemperature = edgeTemperature
      outputArg EdgePlanktivoreLMavgROILatitude = edgeLatitude
      outputArg EdgePlanktivoreLMavgROILongitude = edgeLongitude
    }

    syslog info "GoDown, PlanktivoreLMavgROIPeakThresh, PeakPlanktivoreLMavgROI, PeakPlanktivoreLMavgROIDepth, EdgePlanktivoreLMavgROI, EdgePlanktivoreLMavgROIDepth = "
         + GoDown~bool + ", " + PlanktivoreLMavgROIPeakThresh~count_per_second + ", "
         + PeakPlanktivoreLMavgROI~count_per_second + ", " + PeakPlanktivoreLMavgROIDepth~meter + ", "
         + EdgePlanktivoreLMavgROI~count_per_second + ", " + EdgePlanktivoreLMavgROIDepth~meter

    sendData service=express (
      PeakPlanktivoreLMavgROI,
      PeakPlanktivoreLMavgROIDepth,
      EdgePlanktivoreLMavgROI,
      EdgePlanktivoreLMavgROIDepth
    )
  }

  aggregate PeakDepthAvgProfilesPlanktivoreLMavgROI {
    run while (
      PeakDepthAvgProfilesPlanktivoreLMavgROIActive
    )

    # In "run while", the behavior's initialize() functions runs on init, but the redefinearg (in the mission that calls Science.tl) doesn't happen until the next cycle. The following line is a work-around to ensure redefinearg (in the mission that calls Science.tl) is taken by the behavior.. Don't delete.
    syslog debug "PeakDetectHorizontal"

    behavior Trigger:PeakDetectHorizontal {
      run in sequence

      # Set patchTracking to false because the purpose here is not for patch tracking but for reporting peak depth etc. at every attitude flip (ascent to descent or conversely) on yo-yo profiles. See PeakDetectHorizontal.cpp.
      set patchTracking = false
      set detectFrom = PeakPlanktivoreLMavgROI
      set depthFrom = PeakPlanktivoreLMavgROIDepth
      set latitudeFrom = PeakPlanktivoreLMavgROILatitude
      set longitudeFrom = PeakPlanktivoreLMavgROILongitude
      set filterWidth = FilterWidthHorizontal
      outputArg PeakPlanktivoreLMavgROIAvgProfiles = peakDetect
      outputArg PeakPlanktivoreLMavgROIDepthAvgProfiles = peakDepth
    }
  }

  aggregate PeakDetectPlanktivoreHMavgROI {
    run while ( PeakDetectPlanktivoreHMavgROIActive )

    # The following line is a work-around to ensure redefinearg (in the mission that calls Science.tl) is taken by the behavior. Don't delete.
    syslog debug "PeakDetectVsDepth"

    behavior Trigger:PeakDetectVsDepth {
      run in sequence

      set detect = "_.planktivore_HM_AvgRois"
      set timeWindowPeakReport = TimeWindowPeakReport
      set windowLength = LowPassWindowLength
      set medianFilterLength = MedianFilterLen
      set shallowBound = ShallowBound
      set deepBound = DeepBound
      set depthChangeThresh = DepChangeThreshForAttitudeFlip
      outputArg PeakPlanktivoreHMavgROI = peakDetect
      outputArg PeakPlanktivoreHMavgROIDepth = peakDepth
      outputArg PeakPlanktivoreHMavgROITemperature = peakTemperature
      outputArg PeakPlanktivoreHMavgROILatitude = peakLatitude
      outputArg PeakPlanktivoreHMavgROILongitude = peakLongitude
    }

    # debug
    #         <Syslog Severity="Important">PeakPlanktivoreHMavgROI, PeakPlanktivoreHMavgROILatitude, PeakPlanktivoreHMavgROILongitude = <Arg Name="PeakPlanktivoreHMavgROI"/><Units:count_per_second/>, <Arg Name="PeakPlanktivoreHMavgROILatitude"/><Units:degree/>, <Arg Name="PeakPlanktivoreHMavgROILongitude"/><Units:degree/></Syslog>

    sendData service=express (
      PeakPlanktivoreHMavgROI,
      PeakPlanktivoreHMavgROIDepth
    )
  }

  aggregate EdgeDetectPlanktivoreHMavgROI {
    run while ( EdgeDetectPlanktivoreHMavgROIActive )

    # The following line is a work-around to ensure redefinearg (in the mission that calls Science.tl) is taken by the behavior. Don't delete.
    syslog debug "EdgeDetectVsDepth"

    behavior Trigger:EdgeDetectVsDepth {
      run in sequence

      set detect = "_.planktivore_HM_AvgRois"
      set windowLength = LowPassWindowLength
      set medianFilterLength = MedianFilterLen
      set shallowBound = ShallowBound
      set deepBound = DeepBound
      set offpeakFractionAscent = OffPeakFractionVerticalAscent
      set offpeakFractionDescent = OffPeakFractionVerticalDescent
      set depthChangeThresh = DepChangeThreshForAttitudeFlip
      set peakThresh = PlanktivoreHMavgROIPeakThresh
      set numLayers = NumberOfLayers
      outputArg GoDown = goDown
      outputArg PeakPlanktivoreHMavgROI = peakDetect
      outputArg PeakPlanktivoreHMavgROIDepth = peakDepth
      outputArg PeakPlanktivoreHMavgROITemperature = peakTemperature
      outputArg PeakPlanktivoreHMavgROILatitude = peakLatitude
      outputArg PeakPlanktivoreHMavgROILongitude = peakLongitude
      outputArg EdgePlanktivoreHMavgROI = edgeDetect
      outputArg EdgePlanktivoreHMavgROIDepth = edgeDepth
      outputArg EdgePlanktivoreHMavgROITemperature = edgeTemperature
      outputArg EdgePlanktivoreHMavgROILatitude = edgeLatitude
      outputArg EdgePlanktivoreHMavgROILongitude = edgeLongitude
    }

    syslog info "GoDown, PlanktivoreHMavgROIPeakThresh, PeakPlanktivoreHMavgROI, PeakPlanktivoreHMavgROIDepth, EdgePlanktivoreHMavgROI, EdgePlanktivoreHMavgROIDepth = "
         + GoDown~bool + ", " + PlanktivoreHMavgROIPeakThresh~count_per_second + ", "
         + PeakPlanktivoreHMavgROI~count_per_second + ", " + PeakPlanktivoreHMavgROIDepth~meter + ", "
         + EdgePlanktivoreHMavgROI~count_per_second + ", " + EdgePlanktivoreHMavgROIDepth~meter

    sendData service=express (
      PeakPlanktivoreHMavgROI,
      PeakPlanktivoreHMavgROIDepth,
      EdgePlanktivoreHMavgROI,
      EdgePlanktivoreHMavgROIDepth
    )
  }

  aggregate PeakDetectPlanktivoreDiatoms {
    run while ( PeakDetectPlanktivoreDiatomsActive )

    # The following line is a work-around to ensure redefinearg (in the mission that calls Science.tl) is taken by the behavior. Don't delete.
    syslog debug "PeakDetectVsDepth"

    behavior Trigger:PeakDetectVsDepth {
      run in sequence

      set detect = "_.planktivore_diatoms"
      set timeWindowPeakReport = TimeWindowPeakReport
      set windowLength = LowPassWindowLength
      set medianFilterLength = MedianFilterLen
      set shallowBound = ShallowBound
      set deepBound = DeepBound
      set depthChangeThresh = DepChangeThreshForAttitudeFlip
      outputArg PeakPlanktivoreDiatoms = peakDetect
      outputArg PeakPlanktivoreDiatomsDepth = peakDepth
      outputArg PeakPlanktivoreDiatomsTemperature = peakTemperature
      outputArg PeakPlanktivoreDiatomsLatitude = peakLatitude
      outputArg PeakPlanktivoreDiatomsLongitude = peakLongitude
    }

    sendData service=express (
      PeakPlanktivoreDiatoms,
      PeakPlanktivoreDiatomsDepth
    )
  }

  aggregate EdgeDetectPlanktivoreDiatoms {
    run while ( EdgeDetectPlanktivoreDiatomsActive )

    # The following line is a work-around to ensure redefinearg (in the mission that calls Science.tl) is taken by the behavior. Don't delete.
    syslog debug "EdgeDetectVsDepth"

    behavior Trigger:EdgeDetectVsDepth {
      run in sequence

      set detect = "_.planktivore_diatoms"
      set windowLength = LowPassWindowLength
      set medianFilterLength = MedianFilterLen
      set shallowBound = ShallowBound
      set deepBound = DeepBound
      set offpeakFractionAscent = OffPeakFractionVerticalAscent
      set offpeakFractionDescent = OffPeakFractionVerticalDescent
      set depthChangeThresh = DepChangeThreshForAttitudeFlip
      set peakThresh = PlanktivoreDiatomsPeakThresh
      set numLayers = NumberOfLayers
      outputArg GoDown = goDown
      outputArg PeakPlanktivoreDiatoms = peakDetect
      outputArg PeakPlanktivoreDiatomsDepth = peakDepth
      outputArg PeakPlanktivoreDiatomsTemperature = peakTemperature
      outputArg PeakPlanktivoreDiatomsLatitude = peakLatitude
      outputArg PeakPlanktivoreDiatomsLongitude = peakLongitude
      outputArg EdgePlanktivoreDiatoms = edgeDetect
      outputArg EdgePlanktivoreDiatomsDepth = edgeDepth
      outputArg EdgePlanktivoreDiatomsTemperature = edgeTemperature
      outputArg EdgePlanktivoreDiatomsLatitude = edgeLatitude
      outputArg EdgePlanktivoreDiatomsLongitude = edgeLongitude
    }

    syslog info "GoDown, PlanktivoreDiatomsPeakThresh, PeakPlanktivoreDiatoms, PeakPlanktivoreDiatomsDepth, EdgePlanktivoreDiatoms, EdgePlanktivoreDiatomsDepth = "
         + GoDown~bool + ", " + PlanktivoreDiatomsPeakThresh~count_per_milliliter + ", "
         + PeakPlanktivoreDiatoms~count_per_milliliter + ", " + PeakPlanktivoreDiatomsDepth~meter + ", "
         + EdgePlanktivoreDiatoms~count_per_milliliter + ", " + EdgePlanktivoreDiatomsDepth~meter

    sendData service=express (
      PeakPlanktivoreDiatoms,
      PeakPlanktivoreDiatomsDepth,
      EdgePlanktivoreDiatoms,
      EdgePlanktivoreDiatomsDepth
    )
  }

  aggregate PeakDetectPlanktivoreDinoflagellates {
    run while (
      PeakDetectPlanktivoreDinoflagellatesActive
    )

    # The following line is a work-around to ensure redefinearg (in the mission that calls Science.tl) is taken by the behavior. Don't delete.
    syslog debug "PeakDetectVsDepth"

    behavior Trigger:PeakDetectVsDepth {
      run in sequence

      set detect = "_.planktivore_dinoflagellates"
      set timeWindowPeakReport = TimeWindowPeakReport
      set windowLength = LowPassWindowLength
      set medianFilterLength = MedianFilterLen
      set shallowBound = ShallowBound
      set deepBound = DeepBound
      set depthChangeThresh = DepChangeThreshForAttitudeFlip
      outputArg PeakPlanktivoreDinoflagellates = peakDetect
      outputArg PeakPlanktivoreDinoflagellatesDepth = peakDepth
      outputArg PeakPlanktivoreDinoflagellatesTemperature = peakTemperature
      outputArg PeakPlanktivoreDinoflagellatesLatitude = peakLatitude
      outputArg PeakPlanktivoreDinoflagellatesLongitude = peakLongitude
    }

    sendData service=express (
      PeakPlanktivoreDinoflagellates,
      PeakPlanktivoreDinoflagellatesDepth
    )
  }

  aggregate EdgeDetectPlanktivoreDinoflagellates {
    run while (
      EdgeDetectPlanktivoreDinoflagellatesActive
    )

    # The following line is a work-around to ensure redefinearg (in the mission that calls Science.tl) is taken by the behavior. Don't delete.
    syslog debug "EdgeDetectVsDepth"

    behavior Trigger:EdgeDetectVsDepth {
      run in sequence

      set detect = "_.planktivore_dinoflagellates"
      set windowLength = LowPassWindowLength
      set medianFilterLength = MedianFilterLen
      set shallowBound = ShallowBound
      set deepBound = DeepBound
      set offpeakFractionAscent = OffPeakFractionVerticalAscent
      set offpeakFractionDescent = OffPeakFractionVerticalDescent
      set depthChangeThresh = DepChangeThreshForAttitudeFlip
      set peakThresh = PlanktivoreDinoflagellatesPeakThresh
      set numLayers = NumberOfLayers
      outputArg GoDown = goDown
      outputArg PeakPlanktivoreDinoflagellates = peakDetect
      outputArg PeakPlanktivoreDinoflagellatesDepth = peakDepth
      outputArg PeakPlanktivoreDinoflagellatesTemperature = peakTemperature
      outputArg PeakPlanktivoreDinoflagellatesLatitude = peakLatitude
      outputArg PeakPlanktivoreDinoflagellatesLongitude = peakLongitude
      outputArg EdgePlanktivoreDinoflagellates = edgeDetect
      outputArg EdgePlanktivoreDinoflagellatesDepth = edgeDepth
      outputArg EdgePlanktivoreDinoflagellatesTemperature = edgeTemperature
      outputArg EdgePlanktivoreDinoflagellatesLatitude = edgeLatitude
      outputArg EdgePlanktivoreDinoflagellatesLongitude = edgeLongitude
    }

    syslog info "GoDown, PlanktivoreDinoflagellatesPeakThresh, PeakPlanktivoreDinoflagellates, PeakPlanktivoreDinoflagellatesDepth, EdgePlanktivoreDinoflagellates, EdgePlanktivoreDinoflagellatesDepth = "
         + GoDown~bool + ", " + PlanktivoreDinoflagellatesPeakThresh~count_per_milliliter + ", "
         + PeakPlanktivoreDinoflagellates~count_per_milliliter + ", "
         + PeakPlanktivoreDinoflagellatesDepth~meter + ", "
         + EdgePlanktivoreDinoflagellates~count_per_milliliter + ", "
         + EdgePlanktivoreDinoflagellatesDepth~meter

    sendData service=express (
      PeakPlanktivoreDinoflagellates,
      PeakPlanktivoreDinoflagellatesDepth,
      EdgePlanktivoreDinoflagellates,
      EdgePlanktivoreDinoflagellatesDepth
    )
  }

  aggregate ChlThreshTrigger {
    run while ( ChlThreshTriggerActive )

    behavior Trigger:ValueDetect {
      run in sequence

      set detect = PeakChl
      set lowerThreshold = ChlLowerThresh
      set upperThreshold = ChlUpperThresh
      set numProfilesThreshold = NumProfilesThresh
      outputArg ChlTriggering = outputValue
    }

    assign in sequence TriggeredOnChl = true

    syslog important "Triggered. PeakChl values on " + NumProfilesThresh~count
         + " consecutive yo-yo profiles fall in [" + ChlLowerThresh~microgram_per_liter
         + ChlUpperThresh~microgram_per_liter + "] (NaN bound is ignored)."
  }
}